Скрипт Центральный замок ( пиу пиу... ) на купленную технику

1. Положите папку "sounds", полученную из архива,https://yadi.sk/d/bmW4LHQHaeozs в папку вашей миссии
2. Создайте папку "custom" в папке вашей миссии
3. Распакуйте ваш "dayz_code.pbo", возьмите оттуда эти файлы

...\dayz_code\compile\fn_gearMenuChecks.sqf, ...\dayz_code\init\compiles.sqf ...dayz_code\compile\local_lockUnlock.sqf и ...\dayz_code\compile\ui_selectSlot.sqf

и поместите в папку "custom" вашей миссии

4. Откройте ...\MPMissions\DayZ_Epoch_24.Napf\custom\local_lockUnlock.sqf и замените весь текст в нем на этот:

private ["_vehicle","_status","_sounddist"];
_vehicle = _this select 0;
_status = _this select 1;
_sounddist = 20;

if (local _vehicle) then {
    if(_status) then {
        _vehicle setVehicleLock "LOCKED";
        player action ["lightOn", _vehicle];
        _nul = [objNull, _vehicle, rSAY, "carLock", _sounddist] call RE;
        sleep 0.5;
        player action ["lightOff", _vehicle];
    } else {
        _vehicle setVehicleLock "UNLOCKED";
        player action ["lightOn", _vehicle];
        _nul = [objNull, _vehicle, rSAY, "carLock", _sounddist] call RE;
        sleep 0.5;
        player action ["lightOff", _vehicle];
    };
};

 

5. Откройте ...\MPMissions\DayZ_Epoch_24.Napf\custom\ui_selectSlot.sqf и найдите:

private ["_control","_button","_parent","_group","_pos","_item","_conf","_name","_cfgActions","_numActions","_height","_menu","_config","_type","_script","_outputOriented","_compile","_array","_outputClass","_outputType"];

и замените на:

private ["_control","_button","_parent","_group","_pos","_item","_conf","_name","_cfgActions","_numActions","_height","_menu","_config","_type","_script","_outputOriented","_compile","_array","_outputClass","_outputType","_key_colors","_ownerKeyId","_itemsPlayer","_hasKey","_objects","_ownerID","_i"];

 

6. Там же найдите:

_pos set [3,_height];

и добавьте выше:

        _itemsPlayer = items player;
        
        _temp_keys = [];
        _temp_keys_names = [];
        // find available keys
        _key_colors = ["ItemKeyYellow","ItemKeyBlue","ItemKeyRed","ItemKeyGreen","ItemKeyBlack"];
        if (configName(inheritsFrom(configFile >> "CfgWeapons" >> _item)) in _key_colors) then {
            _ownerKeyId = getNumber(configFile >> "CfgWeapons" >> _item >> "keyid");
            _ownerKeyName = getText(configFile >> "CfgWeapons" >> _item >> "displayName");
            _temp_keys_names set [_ownerKeyId,_ownerKeyName];
            
            _objects = nearestObjects [getPos player, ["LandVehicle","Helicopter","Plane","Ship"], 50];
            _i = 0;
            {
                if (alive _x) then {
                    _ownerID = _x getVariable ["CharacterID", "0"];
                    _hasKey = (_ownerID == str(_ownerKeyId));
                    _oldOwner = (_ownerID == dayz_playerUID);

                    if(_hasKey or _oldOwner) then {
                        if(locked _x) then {
                            //Unlock
                            _menu =  _parent displayCtrl (1600 + _numActions);
                            _menu ctrlShow true;
                            _text =  "Unlock";
                            _script =  "[""" + _ownerID + """] execVM ""scripts\remote_unlock.sqf""";
                            _height = _height + (0.025 * safezoneH);
                            uiNamespace setVariable ['uiControl', _control];
                            _menu ctrlSetText _text;
                            _menu ctrlSetEventHandler ["ButtonClick",_script];
                        } else {
                            //Lock
                            _menu =  _parent displayCtrl (1600 + _numActions);
                            _menu ctrlShow true;
                            _text =  "Lock";
                            _script =  "[""" + _ownerID + """] execVM ""scripts\remote_lock.sqf""";
                            _height = _height + (0.025 * safezoneH);
                            uiNamespace setVariable ['uiControl', _control];
                            _menu ctrlSetText _text;
                            _menu ctrlSetEventHandler ["ButtonClick",_script];
                        };
                        //Engine start
                        _menu =  _parent displayCtrl (1600 + _numActions + 1);
                        _menu ctrlShow true;
                        _text =  "Engine";
                        _script =  "[""" + _ownerID + """] execVM ""scripts\remote_engine.sqf""";
                        _height = _height + (0.025 * safezoneH);
                        uiNamespace setVariable ['uiControl', _control];
                        _menu ctrlSetText _text;
                        _menu ctrlSetEventHandler ["ButtonClick",_script];
                    };
                    
                    _i = _i + 1;
                };
            } forEach _objects;
        };

 

7. Откройте ...\MPMissions\DayZ_Epoch_24.Napf\custom\fn_gearMenuChecks.sqf и найдите:

if((locked _cTarget) && _isOk && (((vehicle player) distance _cTarget) < 12)) then {

и замените на:

if((locked _cTarget) && _isOk && !_inVehicle && (((vehicle player) distance _cTarget) < 12)) then {

 

8. Создайте файл "remote_lock.sqf", в папке "scripts" вашей миссии, с таким содержанием:

private ["_ownerID","_objects","_i","_ownerID2","_vehicle"];
_ownerID = _this select 0;
_objects = nearestObjects [getPos player, ["LandVehicle","Helicopter","Plane","Ship"], 50];
_i = 0;
{
    _vehicle = _x;
    if (alive _vehicle) then {
        _ownerID2 = _vehicle getVariable ["CharacterID", "0"];
        if(_ownerID == _ownerID2) then {
            if(!locked _vehicle) then {
                if(player distance _vehicle < 50) then {
                    DZE_ActionInProgress = true;
                    {player removeAction _x} forEach s_player_lockunlock;s_player_lockunlock = [];
                    s_player_lockUnlock_crtl = 1;
                    PVDZE_veh_Lock = [_vehicle,true];
                    if (local _vehicle) then {
                        PVDZE_veh_Lock spawn local_lockUnlock
                    } else {
                        publicVariable "PVDZE_veh_Lock";
                    };
                    titleText ["Ваш транспорт закрыт","PLAIN DOWN"];
                    s_player_lockUnlock_crtl = -1;
                    DZE_ActionInProgress = false;
                };
            };
        };
        _i = _i + 1;
    };
} forEach _objects;

9. Создайте файл "remote_unlock.sqf", в папке "scripts" вашей миссии, с таким содержанием:

private ["_ownerID","_objects","_i","_ownerID2","_vehicle"];
_ownerID = _this select 0;
_objects = nearestObjects [getPos player, ["LandVehicle","Helicopter","Plane","Ship"], 50];
_i = 0;
{
    _vehicle = _x;
    if (alive _vehicle) then {
        _ownerID2 = _vehicle getVariable ["CharacterID", "0"];
        
        if(_ownerID == _ownerID2) then {
            if(locked _vehicle) then {
                if(player distance _vehicle < 50) then {
                    DZE_ActionInProgress = true;
                    {player removeAction _x} forEach s_player_lockunlock;s_player_lockunlock = [];
                    s_player_lockUnlock_crtl = 1;
                    PVDZE_veh_Lock = [_vehicle,false];
                    if (local _vehicle) then {
                        PVDZE_veh_Lock spawn local_lockUnlock
                    } else {
                        publicVariable "PVDZE_veh_Lock";
                    };
                    titleText ["Ваш транспорт открыт","PLAIN DOWN"];
                    s_player_lockUnlock_crtl = -1;
                    DZE_ActionInProgress = false;
                };
            };
        };
        _i = _i + 1;
    };
} forEach _objects;

10. Создайте файл "remote_engine.sqf", в папке "scripts" вашей миссии, с таким содержанием:

private ["_ownerID","_objects","_i","_ownerID2","_vehicle","_driver","_aigroup"];
_ownerID = _this select 0;
_objects = nearestObjects [getPos player, ["LandVehicle","Helicopter","Plane","Ship"], 50];
_i = 0;
{
    _vehicle = _x;
    if (alive _vehicle) then {
        _ownerID2 = _vehicle getVariable ["CharacterID", "0"];

        if(_ownerID == _ownerID2) then {
            if(!locked _vehicle) then {
                if(player distance _vehicle < 50) then {
                    DZE_ActionInProgress = true;
                    if (isEngineOn _vehicle) then {
                        player action ["engineOff", _vehicle];
                    } else {
                        player action ["engineOn", _vehicle];
                    };
                    player action ["engineOn", _vehicle];
                    DZE_ActionInProgress = false;
                };
            };
        };
        _i = _i + 1;
    };
} forEach _objects;

 

11. Откройте ...\MPMissions\DayZ_Epoch_24.Napf\custom\compiles.sqf и найдите:

player_selectSlot =            compile preprocessFileLineNumbers "\z\addons\dayz_code\compile\ui_selectSlot.sqf";

замените на:

player_selectSlot =            compile preprocessFileLineNumbers "custom\ui_selectSlot.sqf";

найдите:

fn_gearMenuChecks =            compile preprocessFileLineNumbers "\z\addons\dayz_code\compile\fn_gearMenuChecks.sqf";

замените на:

fn_gearMenuChecks =            compile preprocessFileLineNumbers "custom\fn_gearMenuChecks.sqf";

 

найдите:

local_lockUnlock =            compile preprocessFileLineNumbers "\z\addons\dayz_code\compile\local_lockUnlock.sqf";

замените на:

local_lockUnlock =            compile preprocessFileLineNumbers "custom\local_lockUnlock.sqf";

 

12.Откройте ...\MPMissions\DayZ_Epoch_11.Chernarus\init.sqf и найдите:

 

call compile preprocessFileLineNumbers "\z\addons\dayz_code\init\compiles.sqf";

 

замените на:

 

call compile preprocessFileLineNumbers "custom\compiles.sqf";

 

13. Откройте ...\MPMissions\DayZ_Epoch_24.Napf\description.ext и найдите:

 

class RscLoadingText : RscText

 

добавьте выше:

class CfgSounds
{
    sounds[] =
    {
        carLock
    };
    class carLock
    {
        name="carLock";
        sound[] = {"sounds\carlock.ogg",0.9,1};
        titles[] = {};
    };
};

Вот и все   Пользуйтесь на здоровье :yes:

 

 

Посмотреть видео:

 

 

Изменено 18 февраля, 2015 пользователем ATAMAH (история изменений)

Спасибки)

ты кажется забыл про local_lockUnlock.sqf

да ты забыл!!!))) создать в папке custom фаил local_lockUnlock.sqf  с содержанием

 

 

private ["_vehicle","_status","_sounddist"];
_vehicle = _this select 0;
_status = _this select 1;
_sounddist = 20;

if (local _vehicle) then {
    if(_status) then {
        _vehicle setVehicleLock "LOCKED";
        player action ["lightOn", _vehicle];
        _nul = [objNull, _vehicle, rSAY, "carLock", _sounddist] call RE;
        sleep 0.5;
        player action ["lightOff", _vehicle];
    } else {
        _vehicle setVehicleLock "UNLOCKED";
        player action ["lightOn", _vehicle];
        _nul = [objNull, _vehicle, rSAY, "carLock", _sounddist] call RE;
        sleep 0.5;
        player action ["lightOff", _vehicle];
    };
};
 

 

 

и так же прописать этот файлик в compiles.sqf заменив старый)))

 

в файле local_lockUnlock.sqf  есть 

 

sounddist = 20
 

 

 это дальность звучания радиус в метрах
 

в файле ui_selectSlot.sqf есть строка

 

_objects = nearestObjects [getPos player, ["LandVehicle","Helicopter","Plane","Ship"], 500];

 

так вот цифра дистанция на которую работает сигналка в метрах я 500 выкрутил) эта строка в большом скрипте из гайда, смотреть пункт 5)))
 

 в файле fn_gearMenuChecks.sqf есть строка

 

if((locked _cTarget) && _isOk && !_inVehicle && (((vehicle player) distance _cTarget) < 7))
 

 

цифра определяет дальность лутания машины)))) я выставил 7)) как то прикололся 500 поставил)) за полкилометра залутал урал просто посмотрев на него))))

Изменено 29 августа, 2014 пользователем vaness666vad666
Оформил как надо. (история изменений)

ты кажется забыл про local_lockUnlock.sqf

Нет, не забыл, у меня он просто всегда в папке миссии, так как у меня стоит запрет на буксировку закрытой техники. Потому я как то и не задумывался работает без него или нет.

Нет, не забыл, у меня он просто всегда в папке миссии, так как у меня стоит запрет на буксировку закрытой техники. Потому я как то и не задумывался работает без него или нет.

кажется без  local_lockUnlock.sqf пиу пиу не работет так как в нем дальность звучания установлена и фары не мигают про этом пиу пиу)))

 

кажется без  local_lockUnlock.sqf пиу пиу не работет так как в нем дальность звучания установлена и фары не мигают про этом пиу пиу)))

Ты был прав, я совсем забыл что этот файл то же подлежит изменениям. Но уже все норм, гайд исправил )

Стоял на прошлом сервере это скрипт, все нормально работало, потом поменял карту и как раз тут гайд удалили прошлый, в общем восстановил все сам, потом сверился с этим гайдом, все верно, все везде правильно, когда машину открываешь-закрываешь как обычно даже звуки воспроизводятся, а вот меню на ключе посему то так и не показывается ((  Понимаю что связанно это с файлом ui_selectSlot.sqf, но вот найти в чем беда не получается ((

 

 

Стоял на прошлом сервере это скрипт, все нормально работало, потом поменял карту и как раз тут гайд удалили прошлый, в общем восстановил все сам, потом сверился с этим гайдом, все верно, все везде правильно, когда машину открываешь-закрываешь как обычно даже звуки воспроизводятся, а вот меню на ключе посему то так и не показывается ((  Понимаю что связанно это с файлом ui_selectSlot.sqf, но вот найти в чем беда не получается ((

Быть такого не может, перепроверь еще раз все по гайду, где то полюбому что то не совпадает

Сделал себе на сервер. Все работает! 

Изменено 2 сентября, 2014 пользователем Alex3 (история изменений)

Ребят.Всё работает.Тока фары моргать начинают при закрытии открытии только после того как в машину игрок сядет.И двигатель заводится только у того,кто кнопку нажал.или мб Это нормально?

Все работает только бы ещё двигатель дистанционно вырубал было бы оч даже нечего))

Привет всем, немного доработал, чтобы при открытии было пиу-пиу, а при закрытии просто пиу, ну и фары чтобы моргали соответственно действию.

Для этого в description.ext меняем предложенный текст

 

class CfgSounds

{
sounds[] =
{
carLock
};
class carLock
{
name="carLock";
sound[] = {"sounds\carlock.ogg",0.9,1};
titles[] = {};
};
};

 

на этот

 

class CfgSounds
{
sounds[] =
{
carLock;
carUnLock
};
class carLock
{
name="carLock";
sound[] = {"sounds\carlock.ogg",0.9,1};
titles[] = {};
};
class carUnLock
{
name="carUnLock";
sound[] = {"sounds\carunlock.ogg",0.9,1};
titles[] = {};
};
};

 

Далее в local_lockUnlock.sqf вместо

 

} else {
_vehicle setVehicleLock "UNLOCKED";
player action ["lightOn", _vehicle];
_nul = [objNull, _vehicle, rSAY, "carLock", _sounddist] call RE;
sleep 0.5;
player action ["lightOff", _vehicle];

 

 

вставляем это

 

} else {
_vehicle setVehicleLock "UNLOCKED";
player action ["lightOn", _vehicle];
_nul = [objNull, _vehicle, rSAY, "carUnLock", _sounddist] call RE;
sleep 0.4;
player action ["lightOff", _vehicle];
sleep 0.2;
player action ["lightOn", _vehicle];
sleep 0.4;
player action ["lightOff", _vehicle];

 

 

Для этого понадобятся два звуковых файла https://yadi.sk/d/5FJU7aJwbh6aS

Если что сильно не пинайте :)

Мигать фонари начинает только после того как сядешь и выйдешь с машины

У меня нету файла compiles.sqf в папке \custom

"2. Создайте папку "custom" в папке вашей миссии

3. Распакуйте ваш "dayz_code.bpo", возьмите оттуда 3 файла

...\dayz_code\compile\fn_gearMenuChecks.sqf, ...dayz_code\compile\local_lockUnlock.sqf и ...\dayz_code\compile\ui_selectSlot.sqf

и поместите в папку "custom" вашей миссии"

Может в п.3 пропустили добавить файл compiles.sqf?