Не отображается id сейфа

Gromillla · July 3, 2016

Доброго времени суток господа.

Установлен скрипт по отображению логов операций с сейфами, но в rpt вместо id сейфа пишет просто "из Safe(Ид:VaultStorage)" в коде скрипта стоит

%1 положил %2 %3 из %4(Ид:%5)

Откуда берутся эти "%1, %2, %5 и т.д."?

Видимо %5 неверное значение, хотелось бы узнать весь список этих %.

Спасибо.

svalom · July 3, 2016

Будьте добры выложить хотябы пару строчек кода из которого Вы взяли текст "%1 положил %2 %3 из %4(Ид:%5)"

Edited July 3, 2016 by svalom (see edit history)

pekar0201 · July 3, 2016

М.Б. Криво поставил

Gromillla · July 3, 2016

Будьте добры выложить хотябы пару строчек кода из которого Вы взяли текст "%1 положил %2 %3 из %4(Ид:%5)"

#include "ZSCconfig.sqf"

call compile preprocessFileLineNumbers "ZSC\gold\player_traderMenu.sqf";

BIS_fnc_numberDigits = compile preprocessFileLineNumbers "ZSC\compiles\numberDigits.sqf";
BIS_fnc_numberText = compile preprocessFileLineNumbers "ZSC\compiles\numberText.sqf"; 
SC_fnc_removeCoins = compile preprocessFileLineNumbers "ZSC\compiles\SC_fnc_removeCoins.sqf";
SC_fnc_addCoins = compile preprocessFileLineNumbers "ZSC\compiles\SC_fnc_addCoins.sqf";

/*overwrites*/
if( isNil "ZSC_Overwrite_SelfActions" || ZSC_Overwrite_SelfActions)then{
fnc_usec_selfActions = compile preprocessFileLineNumbers "Scripts\fn_selfActions.sqf";
};
if( isNil "ZSC_Overwrite_SwitchModel" || ZSC_Overwrite_SwitchModel)then{
player_switchModel = compile preprocessFileLineNumbers "custom\player_switchModel.sqf";
};
if( isNil "ZSC_Overwrite_LockVault" || ZSC_Overwrite_LockVault)then{
player_lockVault =			compile preprocessFileLineNumbers "custom\player_lockVault.sqf";
};
if( isNil "ZSC_Overwrite_UnLockVault" || ZSC_Overwrite_UnLockVault)then{
player_unlockVault =			compile preprocessFileLineNumbers "custom\player_unlockVault.sqf";
};
if( isNil "ZSC_Overwrite_PackVault" || ZSC_Overwrite_PackVault)then{
player_packVault =			compile preprocessFileLineNumbers "ZSC\compiles\player_packVault.sqf";
};
if( isNil "ZSC_Overwrite_PackTent" || ZSC_Overwrite_PackTent)then{
player_packTent =			compile preprocessFileLineNumbers "ZSC\compiles\player_packTent.sqf";
};

player_gearSet	=	compile preprocessFileLineNumbers "ZSC\compiles\player_gearSet.sqf";
//This overwrite must happen, or change the files in your version of it. I Don't know any mod that changes this file tbh.


/*end overwrites*/

BankDialogTransferAmount = 13000;
BankDialogPlayerBalance = 13001;
BankDialogBankBalance = 13002;
SCTraderDialogCatList = 32000;
SCTraderDialogItemList = 32001;
SCTraderDialogBuyPrice = 32002;
SCTraderDialogSellPrice = 32003;
GivePlayerDialogTransferAmount = 14000;
GivePlayerDialogPlayerBalance = 14001;

BankDialogUpdateAmounts = {
	_vehicleType = typeOf ZSC_CurrentStorage; 
	if(isClass(configFile >> "CfgVehicles" >> _vehicleType ))then{									
		_vehicleMagazines = getNumber (configFile >> "CfgVehicles" >> _vehicleType >> "transportMaxMagazines");
		_displayName = getText  (configFile >> "CfgVehicles" >> _vehicleType >> "displayName");		
		_sizeOfMoney = _vehicleMagazines * ZSC_MaxMoneyInStorageMultiplier;		
		ctrlSetText [2701, format["%1", _displayName]];
		ctrlSetText [BankDialogPlayerBalance, format["%1 %2", [player getVariable ['cashMoney', 0]] call BIS_fnc_numberText, CurrencyName]];
		ctrlSetText [BankDialogBankBalance, format["%1 / %3 %2", [ZSC_CurrentStorage getVariable ['bankMoney', 0]] call BIS_fnc_numberText, CurrencyName, [_sizeOfMoney] call BIS_fnc_numberText]];
	}else{
		ctrlSetText [BankDialogPlayerBalance, format["Can not get vehicle capacity!","test"]];
		ctrlSetText [BankDialogBankBalance, format["Can not get vehicle capacity!","test"]];
	};
	
};

GivePlayerDialogAmounts = {
	ctrlSetText [GivePlayerDialogPlayerBalance, format["%1 %2", [player getVariable ['cashMoney', 0]] call BIS_fnc_numberText, CurrencyName]];
	ctrlSetText [14003, format["%1", (name ZSC_GiveMoneyTarget)]];
};

BankDialogWithdrawAmount = {
	private ["_amount","_bank","_wealth"];
	
	_amount = parseNumber (_this select 0);	
	_bank = ZSC_CurrentStorage getVariable ["bankMoney", 0];
	_wealth = player getVariable["cashMoney",0];
	_vehicleType = typeOf ZSC_CurrentStorage; 
	_displayName = getText  (configFile >> "CfgVehicles" >> _vehicleType >> "displayName");		
	
	if (!isNull ZSC_CurrentStorage) then {
	
	if (_amount < 1 or _amount > _bank) exitWith {
		cutText [format["Вы не можете снять больше, чем %1.",_displayName], "PLAIN DOWN"];
	};

	player setVariable["cashMoney",(_wealth + _amount),true];
	ZSC_CurrentStorage setVariable["bankMoney",(_bank - _amount),true];
	
	// логи передачи
PVDZE_atp = format["[Лог передачи денег]:%1 забрал %2 %3 в %4(Ид:%5) Координаты объекта:[%6,%7] GPS:(%8)",name player, [_amount] call BIS_fnc_numberText,CurrencyName,_displayName,_vehicleType,getDir ZSC_CurrentStorage,getPosATL ZSC_CurrentStorage,mapGridPosition (getPosATL ZSC_CurrentStorage)];
publicVariableServer 'PVDZE_atp';

	PVDZE_plr_Save = [player,(magazines player),true,true] ;
	publicVariableServer "PVDZE_plr_Save";
	
	PVDZE_veh_Update = [ZSC_CurrentStorage,"gear"];
	publicVariableServer "PVDZE_veh_Update";

	cutText [format["Вы взяли %1 %2 из %3", [_amount] call BIS_fnc_numberText, CurrencyName,_displayName], "PLAIN DOWN"];
	}else{
	cutText ["Не удается получить доступ к храненилищу денег. Пожалуйста, попробуйте еще раз.", "PLAIN DOWN"];
};
};

BankDialogDepositAmount = {
	private ["_amount","_bank","_wealth"];	
	_vehicleType = typeOf ZSC_CurrentStorage; 	
	_maxCap = 0;	
	_displayName = "Storage";
	if(isClass(configFile >> "CfgVehicles" >> _vehicleType ))then{	
		_displayName = getText  (configFile >> "CfgVehicles" >> _vehicleType >> "displayName");		
		_vehicleMagazines = getNumber (configFile >> "CfgVehicles" >> _vehicleType >> "transportMaxMagazines");		
		_maxCap = _vehicleMagazines * ZSC_MaxMoneyInStorageMultiplier;	
	}else{		
		_displayName = "Unknown";
	};

	_amount = parseNumber (_this select 0);
	_bank = ZSC_CurrentStorage getVariable ["bankMoney", 0];
	_wealth = player getVariable["cashMoney",0];
	
	if (_amount < 1 or _amount > _wealth) exitWith {
		cutText ["Вы не можете внести больше, чем у вас есть.", "PLAIN DOWN"];
	};

	if( ((_bank + _amount ) >  _maxCap)) then{		
			cutText [format["Вы можете хранить только максимум %1 %2 в этом %3.", [_maxCap] call BIS_fnc_numberText,CurrencyName,_displayName], "PLAIN DOWN"];
	}else{	
		player setVariable["cashMoney",(_wealth - _amount),true];
		ZSC_CurrentStorage setVariable["bankMoney",(_bank + _amount),true];
		
		// логи передачи денег
PVDZE_atp = format["[Лог передачи денег]:%1 положил %2 %3 из %4(Ид:%5) Координаты объекта:[%6,%7] GPS:(%8)",name player, [_amount] call BIS_fnc_numberText,CurrencyName,_displayName,_vehicleType,getDir ZSC_CurrentStorage,getPosATL ZSC_CurrentStorage,mapGridPosition (getPosATL ZSC_CurrentStorage)];
publicVariableServer 'PVDZE_atp';
		
		cutText [format["Вы дали %1 %2 в %3.", [_amount] call BIS_fnc_numberText, CurrencyName,_displayName], "PLAIN DOWN"];
	};
	PVDZE_plr_Save = [player,(magazines player),true,true] ;
	publicVariableServer "PVDZE_plr_Save";
	
	PVDZE_veh_Update = [ZSC_CurrentStorage,"gear"];
	publicVariableServer "PVDZE_veh_Update";
};

GivePlayerAmount = {
	private ["_amount","_target","_wealth"];
	
	_amount = parseNumber (_this select 0);
	_target = ZSC_GiveMoneyTarget;
	_wealth = player getVariable["cashMoney",0];
	_twealth = _target getVariable["cashMoney",0];
	_InTrd = _target getVariable ["TrBsy",false];
	
	if (_amount < 1 or _amount > _wealth) exitWith {
		cutText ["Вы не можете дать больше, чем у вас в настоящее время есть.", "PLAIN DOWN"];
    };

	if (!(isPlayer ZSC_GiveMoneyTarget)) exitWith {
		cutText ["Вы можете только давать деньги игроку", "PLAIN DOWN"];
	};

	 if (_InTrd) exitWith {
        cutText ["Другой игрок уже передает вам деньги,подождите..", "PLAIN DOWN"];
    };
	
	player setVariable["cashMoney",_wealth - _amount, true];

	_target setVariable["cashMoney",_twealth + _amount, true];

	// логи передачи
PVDZE_atp = format["[Лог передачи денег]:Игрок %1 отдал %2 %3 игроку %4 Координаты игрока:[%5,%6] GPS:(%7)",name player,[_amount] call BIS_fnc_numberText,CurrencyName,name _target,getDir player,getPosATL player,mapGridPosition (getPosATL player)];
publicVariableServer 'PVDZE_atp';
	
	PVDZE_plr_Save = [player,(magazines player),true,true] ;
	publicVariableServer "PVDZE_plr_Save";
	PVDZE_plr_Save = [_target,(magazines _target),true,true] ;
	publicVariableServer "PVDZE_plr_Save";

	cutText [format["You gave %1 %2.", _amount, CurrencyName], "PLAIN DOWN"];
};

Gromillla · July 3, 2016

М.Б. Криво поставил

чё там ставить то

RedLink · July 3, 2016

Ид:%5

у тебя отвечает

_vehicleType

тоесть обычное название откуда/куда брали/ложили бабло.

RedLink · July 3, 2016

Чтобы посмотреть именно ID используй эти данные

        _obj = cursortarget;
        _objID = _obj getVariable['ObjectID','0'];

Gromillla · July 4, 2016

Чтобы посмотреть именно ID используй эти данные
        _obj = cursortarget;
        _objID = _obj getVariable['ObjectID','0'];
 

честно говоря не особо понял)

RedLink · July 4, 2016

Вот кусок кода, где показывается именно ID сейфа/локбокса/транспорта. Смотри что изменил и дальше по аналогии поймешь..

BankDialogDepositAmount = {
private ["_amount","_bank","_wealth"];
_obj = cursortarget;
_objID = _obj getVariable['ObjectID','0'];
_vehicleType = typeOf ZSC_CurrentStorage;
_maxCap = 0;
_displayName = "Storage";
if(isClass(configFile >> "CfgVehicles" >> _vehicleType ))then{
_displayName = getText (configFile >> "CfgVehicles" >> _vehicleType >> "displayName");
_vehicleMagazines = getNumber (configFile >> "CfgVehicles" >> _vehicleType >> "transportMaxMagazines");
_maxCap = _vehicleMagazines * ZSC_MaxMoneyInStorageMultiplier;
}else{
_displayName = "Unknown";
};

_amount = parseNumber (_this select 0);
_bank = ZSC_CurrentStorage getVariable ["bankMoney", 0];
_wealth = player getVariable["cashMoney",0];

if (_amount < 1 or _amount > _wealth) exitWith {
cutText ["Вы не можете внести больше, чем у вас есть.", "PLAIN DOWN"];
};

if( ((_bank + _amount ) > _maxCap)) then{
cutText [format["Вы можете хранить только максимум %1 %2 в этом %3.", [_maxCap] call BIS_fnc_numberText,CurrencyName,_displayName], "PLAIN DOWN"];
}else{
player setVariable["cashMoney",(_wealth - _amount),true];
ZSC_CurrentStorage setVariable["bankMoney",(_bank + _amount),true];

// логи передачи денег
PVDZE_atp = format["[Лог передачи денег]:%1 положил %2 %3 из %4(Ид:%5) Координаты объекта:[%6,%7] GPS:(%8)",name player, [_amount] call BIS_fnc_numberText,CurrencyName,_displayName,_objID,getDir ZSC_CurrentStorage,getPosATL ZSC_CurrentStorage,mapGridPosition (getPosATL ZSC_CurrentStorage)];
publicVariableServer 'PVDZE_atp';

cutText [format["Вы дали %1 %2 в %3.", [_amount] call BIS_fnc_numberText, CurrencyName,_displayName], "PLAIN DOWN"];
};
PVDZE_plr_Save = [player,(magazines player),true,true] ;
publicVariableServer "PVDZE_plr_Save";

PVDZE_veh_Update = [ZSC_CurrentStorage,"gear"];
publicVariableServer "PVDZE_veh_Update";
};

NoNameUltima · July 4, 2016

Брошюрку по паскалю, можно прочесть за час-два.(Или пару статей от КилЗонеКид)

Вкинув не нужные темы, о работе с графикой и т.п.

Затем открыть скрипт, и загуглить на сайте богемии АПИ.

Но можно и на форуме часами ждать ответ на элементарный вопрос - как, что, куда.....

Иногда удивляюсь - столько времени тратить на обмусоливание элементарного вопроса, в котором разобраться - часа за 3 можно полностью, да и не только в конкретном вопросе, а вообще по тематике скриптов, и уж тем более под А2\А3

Gromillla · July 5, 2016

Брошюрку по паскалю, можно прочесть за час-два.(Или пару статей от КилЗонеКид)

Вкинув не нужные темы, о работе с графикой и т.п.

Затем открыть скрипт, и загуглить на сайте богемии АПИ.

Но можно и на форуме часами ждать ответ на элементарный вопрос - как, что, куда.....

Иногда удивляюсь - столько времени тратить на обмусоливание элементарного вопроса, в котором разобраться - часа за 3 можно полностью, да и не только в конкретном вопросе, а вообще по тематике скриптов, и уж тем более под А2\А3

я не в курсе кто такой или что такое "КилЗонеКид"

Sign In

Не отображается id сейфа

Share this post

Link to post

Share on other sites

10 answers to this question

Recommended Posts

Share this post

Link to post

Share on other sites

Share this post

Link to post

Share on other sites

Share this post

Link to post

Share on other sites

Share this post

Link to post

Share on other sites

Share this post

Link to post

Share on other sites

Share this post

Link to post

Share on other sites

Share this post

Link to post

Share on other sites

Share this post

Link to post

Share on other sites

Share this post

Link to post

Share on other sites

Share this post

Link to post

Share on other sites

Create an account or sign in to comment

Create an account

Sign in

Similar Content

Our picks

Important Information