Выпадание лута из уничтоженного транспорта (v1.1)

В общем-то этот скрипт выкидывает лут из техники если она была уничтожена. Довольно гибкая настрока. Файл миссии почти не увеличивается, так как всё находится в pbo, в миссии меняет только init.sqf :)

 

Инструкция:
1) В папке compile вашего dayz_server.pbo создаём файл server_crashLoot.sqf со следующим содержимым:

 

 

private["_veh","_gear","_pos","_crashPile","_crashPiles","_element","_objWpnTypes","_objWpnQty","_isOK","_countr","_count","_cont","_temp","_rnd","_lockPrevent","_guaranteedLoot","_randomizedLoot","_radius","_chance"];
_veh = _this;
_gear = _veh getVariable ["lastInventory", []];

if(isNil "DZE_crashLootConfig") then{
    DZE_crashLootConfig = [true,2,5,5,0];
};
    
_lockPrevent = DZE_crashLootConfig select 0;
_guaranteedLoot = DZE_crashLootConfig select 1;
_randomizedLoot = DZE_crashLootConfig select 2;
_radius = DZE_crashLootConfig select 3;
_chance = DZE_crashLootConfig select 4;

_crashPile = objNull;
_crashPiles = [];
_cont = false;


if(_lockPrevent) then{
    if(locked _veh) then{
        _cont = false;
    }else{
        _cont = true;
    };
}else{
    _cont = true;
};

if(((count _gear) > 0) && _cont) then{
    
    //Wait for vehicle to stop moving
    sleep 1;
    _count = 0;
    while{(speed _veh) > 0.1 && _count <= 20} do{
        sleep 0.1;
        _count = _count + 0.1;
    };
    
    //Spawn the loot
    diag_log format["DEAD VEHICLE - server_crashLoot.sqf - %1",_gear];
    
    _pos = getPos _veh;
    _num = round(random _randomizedLoot) + _guaranteedLoot;

    for "_x" from 1 to _num do {
        _temp = createVehicle ["WeaponHolder", [_pos select 0, _pos select 1, 0], [], _radius, "CAN_COLLIDE"];
        _crashPiles = _crashPiles + [_temp];
    };
    
    //Add weapons
    _objWpnTypes = (_gear select 0) select 0;
    _objWpnQty = (_gear select 0) select 1;
    _countr = 0;                    
    {
        if(_x in (DZE_REPLACE_WEAPONS select 0)) then {
            _x = (DZE_REPLACE_WEAPONS select 1) select ((DZE_REPLACE_WEAPONS select 0) find _x);
        };
        _isOK =     isClass(configFile >> "CfgWeapons" >> _x);
        if (_isOK) then {
            _element = floor(random _num);
            _crashPile = _crashPiles select _element;
            for "_i" from 1 to (_objWpnQty select _countr) do {
                _rnd = random 1;
                if(_rnd >= _chance) then{
                    _crashPile addWeaponCargoGlobal [_x,1];
                };
            };
        };
        _countr = _countr + 1;
    } count _objWpnTypes;

    //Add Magazines
    _objWpnTypes = (_gear select 1) select 0;
    _objWpnQty = (_gear select 1) select 1;
    _countr = 0;
    {
        if (_x == "BoltSteel") then { _x = "WoodenArrow" }; // Convert BoltSteel to WoodenArrow
        if (_x == "ItemTent") then { _x = "ItemTentOld" };
        _isOK =     isClass(configFile >> "CfgMagazines" >> _x);
        if (_isOK) then {
            _element = floor(random _num);
            _crashPile = _crashPiles select _element;
            for "_i" from 1 to (_objWpnQty select _countr) do {
                _rnd = random 1;
                if(_rnd >= _chance) then{
                    _crashPile addMagazineCargoGlobal [_x,1];
                };
            };
        };
        _countr = _countr + 1;
    } count _objWpnTypes;
    
    //Add Backpacks
    _objWpnTypes = (_gear select 2) select 0;
    _objWpnQty = (_gear select 2) select 1;
    _countr = 0;
    {
        _isOK =     isClass(configFile >> "CfgVehicles" >> _x);
        if (_isOK) then {
            _element = floor(random _num);
            _crashPile = _crashPiles select _element;
            for "_i" from 1 to (_objWpnQty select _countr) do {
                _rnd = random 1;
                if(_rnd >= _chance) then{
                    _crashPile addBackpackCargoGlobal [_x,1];
                };
            };
        };
        _countr = _countr + 1;
    } count _objWpnTypes;
};

 

 

2) Всё в том же нашем dayz_server находим файл server_monitor.sqf и в нём эту строку:

if (_object isKindOf "AllVehicles") then {

и добавляем это после неё:

_object setVariable ["lastInventory", _intentory];

3) Открываем файл server_updateObject.sqf и находим там строку:

_object setVariable["lastInventory",_inventory];

и заменяем её на это:

if(alive _object) then{
        _object setVariable["lastInventory",_inventory];
    };

теперь находим эти строки:

_object_killed = {
    private["_hitpoints","_array","_hit","_selection","_key","_damage"];

и снизу добавляем этот код:

if(_object isKindOf "AllVehicles") then{
        _object execVM "\z\addons\dayz_server\compile\server_crashLoot.sqf";
    }; 

4) Открываем файлы server_publishVehicle.sqf, server_publishVehicle2.sqf, server_publishVehicle3.sqf и во всех трёх находим эту строку:

publicVariable "PVDZE_veh_Init";

в файле server_publishVehicle3.sqf после этой строки добавляем это:

_object setVariable ["lastInventory", [_weapons,_magazines,_backpacks]];

а в остальных двух это:

_object setVariable ["lastInventory", []];

5) Открываем init.sqf и около переменных DayZ наверху добавляем это:

/*
select 0 = Prevent gear from spawning on locked vehicles (boolean)
select 1 = Guaranteed loot piles (int)
select 2 = Max additional loot piles on top of guaranteed (int)
select 3 = Radius around crash site to spawn loot (double or int)
select 4 = Chance of gear being destroyed (Between 0-1, Ex: 0 = Never lost, 0.5 = Half lost, 1 = All lost)
Default: DZE_crashLootConfig = [true,2,5,5,0];
*/
DZE_crashLootConfig = [true,2,5,5,0];

Значения переменных:

• select 0 - предотвращение спавна лута если машина была закрыта
   → true - включено
   → false - выключено
• select 1 - минимальное количество появляющихся куч с лутом
• select 2 - максимальное количество появляющихся куч с лутом
• select 3 - радиус по которому спавнится лут (отчёт от "трупа" транспорта)
• select 4 - шанс разрушения лута
   → 0 - появляется весь лут что был в технике
   → 1 - лут вообще не появляется

Ставил уже кто-нибудь?

Хорошая шняга, надо попробовать :thumbsup:

Правда если машины была забитаЮ то заколебаешься все собирать, это ж не с одной кучи, а все отдельно, но все равно хорошо тем что самое ценное если было че, то можно уж и понагибаться )

Хорошая шняга, надо попробовать :thumbsup:

 

Правда если машины была забитаЮ то заколебаешься все собирать, это ж не с одной кучи, а все отдельно, но все равно хорошо тем что самое ценное если было че, то можно уж и понагибаться )

Ну как бы можно одну кучу сделать и всё. По крайней мере теперь лут не пропадёт просто так, а ты сможешь собрать что нужно.

 

и добавляем это после неё: _object setVariable ["lastInventory", _intentory];

В слове инвентори ошибка

В слове инвентори ошибка

Код с источника не менял. Сейчас изменю в гайде. Работает после исправления?

В слове инвентори ошибка

Ето не  ошибка ,все правильно

Ето не  ошибка ,все правильно

Там inventoty было. Уже исправил. Хотя копировал код с оригинала. Мб так и надо было хз.

Там inventoty было. Уже исправил. Хотя копировал код с оригинала. Мб так и надо было хз.

в каком именно месте?

 

if (_object isKindOf "AllVehicles") then { и добавляем это после неё: _object setVariable ["lastInventory", _inventory];

Последний код в оригинале такой:

_object setVariable ["lastInventory", _intentory]; 

_intentory

Вот оригинальный гайд

 

Последний код в оригинале такой:

_object setVariable ["lastInventory", _intentory]; 

_intentory

 

Вот оригинальный гайд

да, опечатка

да, опечатка

Короч я исправил получается верно. Теперь только протетсить надо - будет работать или нет?

да, опечатка

Все таки правильно все было, надо назад исправить на "_intentory". Прошу просить меня-это я воду взбаламутил

В 1.0.5.1 выпуска server_monitor.sqf, была орфографическая ошибка слова _inventory, поэтому это _intentory

Edited December 7, 2014 by Bandit3 (see edit history)

Все работает!!! Лично мною проверено и зафиксировано на ютубе )

Все работает!!! Лично мною проверено и зафиксировано на ютубе )

То есть работает именно с intentory?

То есть работает именно с intentory?

Да, именно так!

Да, именно так!

Вернул как было

Помогите, у меня лут выпадает почему то только из легковых  машин например СУВ, УАЗ. Из грузовых и военной техники уже нет. Где ошибка подскажите. 

У меня дюпается. 

У меня дюпается.

Подробнее можно, у себя проверю...

Подробнее можно, у себя проверю...

Заспавни тачку с ключем, потом положи лут. Далее взрываешь идешь ищешь тачку которую спавнил сервер, кладешь туда лут и смотришь под тачку. У меня таким образом дюпался... А потом не важно какая машина все равно дюпает. 

Заспавни тачку с ключем, потом положи лут. Далее взрываешь идешь ищешь тачку которую спавнил сервер, кладешь туда лут и смотришь под тачку. У меня таким образом дюпался... А потом не важно какая машина все равно дюпает. 

попрошу удалить сообщение, а то игроки тут тоже ходят :D

попрошу удалить сообщение, а то игроки тут тоже ходят :D

Зачем пусть все знают и не будут ставить этот скрипт.

Заспавни тачку с ключем, потом положи лут. Далее взрываешь идешь ищешь тачку которую спавнил сервер, кладешь туда лут и смотришь под тачку. У меня таким образом дюпался... А потом не важно какая машина все равно дюпает. 

что то не выходит дюпнуть... не помешало бы на твой DZE_crashLootConfig взглянуть, потому как ставил я процент разрушения лута 0.1 и лут вовсе не выпадал. Есть визуальный баг когда лут выпадает  у уничтоженного транспорта открывается инвентарь, и там виден весь лут что там был , взять его от туда нельзя...