Скрипт Улучшения\апгрейд машин из Origins в DayZ EPOCH

**DrTauren** · 13 мая 2015

Думаю всем понятно что при помощи данного скрипта мы сможем улучшать машины из Origins так же как в одноимённом моде. Имейте ввиду что хотя этот скрипт для EPOCH, он будет бесполезен если на вашем сервер также не активирован мод Origins.

Пожалуйста, Войдите или Зарегистрируйтесь, чтобы увидеть это: Вложение.

Внимание!

Данная версия позволит вам обновлять транспорт при помощи одних лишь запчастей (scrap metal)
Данная версия только для Origins Mod 1.7.9
Все эти минусы будут пофикшены в следующей версии

Нам понадобятся следующие файлы:

variables.sqf
compiles.sqf
fn_selfactions.sqf
object_setFixServer.sqf
server_monitor.sqf
server_updateObject.sqf
server_publishVehicle.sqf

P.S. Я не буду объяснять как делать свои кастомные файлы типа variables.sqf, т.к. это займёт ооочень много времени, к тому же таких туторов уже куча, вы вполне сможете найти и прочитать как сделать кастомный файл

Инструкция:
1) Открываем ваш кастомный variables.sqf и находим эту строку:

// update objects

и сразу после этой строки добавить:

Ori_VehiclesList = ["ori_ScrapBuggy","ori_survivorBus","ori_vil_lada_2105_rust","ori_poldek_black","ori_poldek","ori_rth_originsmod_bathmobile","ori_transit","ori_vil_originsmod_lublin_truck","ori_vil_originsmod_truck_civ","ori_originsmod_pickupoldfuel","ori_p85_originsmod_cucv_pickup","ori_originsmod_pickupold"];  
Ori_VehicleUpgrades = ["pluhPredni","kolaOchrana","oknaOchrana","predniOknoOchrana"];

2) Открываем файл compiles.sqf и находим эту строку:

object_setFixServer = compile preprocessFileLineNumbers "\z\addons\dayz_code\compile\object_setFixServer.sqf";

заменяем её на эту:

object_setFixServer = compile preprocessFileLineNumbers "compile\object_setFixServer.sqf";

и создаём в папке миссии папку compile, а в ней файл object_setFixServer.sqf с таким содержимым:

private ["_unit","_selection","_strH","_damage","_upgrades"];
_unit =            _this select 0;
_selection =    _this select 1;
_damage =        _this select 2;

if (_selection != "" && local _unit) then {
    if (_selection in Ori_VehicleUpgrades) then {
        _unit setVariable [_selection,_damage,true];
        PVDZE_veh_Update = [_unit,"repair"];
    } else {
        _strH = "hit_" + (_selection);
        _unit setHit[_selection,_damage];

        _unit setVariable [_strH,_damage,true];
        if (_damage == 0) then {
            PVDZE_veh_Update = [_unit,"repair"];
        } else {
            PVDZE_veh_Update = [_unit,"damage"];
        };
    };
    
    if (isServer) then {
        PVDZE_veh_Update call server_updateObject;
    } else {
        publicVariableServer "PVDZE_veh_Update";
    };
};

3) Открываем ваш fn_selfaction.sqf и находим там строку:

s_player_repairActions set [count s_player_repairActions,_menu1];

а сразу после неё добавляем этот код:

if (_typeOfCursorTarget in Ori_VehiclesList) then {
            _cfg = configFile >> "CfgVehicles" >> _typeOfCursorTarget >> "AnimationSources";
            _tc = count _cfg;
            _part = "PartGeneric";
            
            for "_mti" from 0 to _tc-1 do {
                _mt = (_cfg select _mti);
                _st = getText(_mt >> "source");
                _anim_array = Ori_VehicleUpgrades;
                if (_st in _anim_array) then {
                    _statuss = _cursorTarget getVariable [_st,1];
                        if (_statuss == 1) then {
                            _num = _anim_array find _st;
                            _upgrade = _anim_array select _num;
                            _upgradeName = "";
                                    switch _upgrade do {
                                    case "pluhPredni" : {_upgradeName = "Front Plow";};
                                    case "kolaOchrana" : {_upgradeName = "Wheel Guards";};
                                    case "oknaOchrana" : {_upgradeName = "Window Guards";};
                                    case "predniOknoOchrana" : {_upgradeName = "Windshield Guards";};
                                };
                            _color = "color='#ff0000'";
                            _stname = format["Upgrade %1",_upgradeName];
                            _string = format["<t %2>%1</t>", _stname,_color];
                        _handle = dayz_myCursorTarget addAction [_string, "custom\ori_upgrade.sqf",[_cursorTarget,_part,_st], 0, false, true, "",""];
                        s_player_repairActions set [count s_player_repairActions,_handle];
                    };
                };
            };
        };

4) В папке миссии создаём папку custom и в ней - файл ori_upgrade.sqf с таким содержимым:

private ["_isOk","_vehicle","_part","_hitpoint","_type","_selection","_array","_started","_finished","_animState","_isMedic","_num_removed","_damage","_dis","_sfx","_allFixed","_id","_hasToolbox","_section","_nameType","_namePart","_hitpoints","_mt","_nameClass1","_st","_cfg","_tc"];

if(DZE_ActionInProgress) exitWith { cutText [(localize "str_epoch_player_92") , "PLAIN DOWN"]; };
DZE_ActionInProgress = true;

_id = _this select 2;
_array =     _this select 3;

_vehicle =     _array select 0;
_part =        _array select 1;
_hitpoint = _array select 2;
_type = typeOf _vehicle; 

//
_hasToolbox =     "ItemToolbox" in items player;
_section = _part in magazines player;

// moving this here because we need to know which part needed if we don't have it
_nameType =         getText(configFile >> "cfgVehicles" >> _type >> "displayName");
_namePart =         getText(configFile >> "cfgMagazines" >> _part >> "displayName");
_isOk = true;
s_player_repair_crtl = 1;

if (_section && _hasToolbox) then {

    player playActionNow "Medic";
    _sfx = "repair";
    _dis=0;
    [player,_sfx,0,false,_dis] call dayz_zombieSpeak;
    [player,_dis,true,(getPosATL player)] spawn player_alertZombies;
    
    r_interrupt = false;
    _animState = animationState player;
    r_doLoop = true;
    _started = false;
    _finished = false;
    
    while {r_doLoop} do {
        _animState = animationState player;
        _isMedic = ["medic",_animState] call fnc_inString;
        if (_isMedic) then {
            _started = true;
        };
        if (_started && !_isMedic) then {
            r_doLoop = false;
            _finished = true;
        };
        if (r_interrupt) then {
            r_doLoop = false;
        };
        sleep 0.1;
    };
    r_doLoop = false;

    if (_finished) then {
        if (_part == "PartGeneric") then {
            player removeMagazine _part;
            
            _cfg = configFile >> "CfgVehicles" >> typeof _vehicle >> "AnimationSources";
            _tc = count _cfg;
            for "_mti" from 0 to _tc-1 do {
                _mt = (_cfg select _mti);
                _nameClass1 = configName(_mt);
                _st = getText(_mt >> "source");
                if (_st==_hitpoint) then { _selection = _st; };
            };
            PVDZE_veh_SFix = [_vehicle,_selection,0];
            publicVariable "PVDZE_veh_SFix";
            if (local _vehicle) then {
                PVDZE_veh_SFix call object_setFixServer;
            };
            
            player playActionNow "Medic";
            sleep 1;
            
            _dis=20;
            _sfx = "repair";
            [player,_sfx,0,false,_dis] call dayz_zombieSpeak;
            [player,_dis,true,(getPosATL player)] spawn player_alertZombies;
            sleep 5;
            _vehicle setvelocity [0,0,1];
            
            //Success!
            cutText [format[(localize "str_epoch_player_166"),_namePart,_nameType], "PLAIN DOWN"];            
        } else {
            _damage = [_vehicle,_hitpoint] call object_getHit;
            _vehicle removeAction _id;
        
            //dont waste loot on undamaged parts
            if (_damage > 0) then {
            
                // ensure part was removed
                _num_removed = ([player,_part] call BIS_fnc_invRemove);

                if(_num_removed == 1) then {

                    //Fix the part
                    _selection = getText(configFile >> "cfgVehicles" >> _type >> "HitPoints" >> _hitpoint >> "name");
            
                    //vehicle is owned by whoever is in it, so we have to have each client try && fix it
                    PVDZE_veh_SFix = [_vehicle,_selection,0];
                    publicVariable "PVDZE_veh_SFix";
                    
                    if (local _vehicle) then {
                        PVDZE_veh_SFix call object_setFixServer;
                    };

                    _vehicle setvelocity [0,0,1];

                    //Success!
                    cutText [format[(localize "str_epoch_player_166"),_namePart,_nameType], "PLAIN DOWN"];

                };
            
            };
        };
    } else {
        r_interrupt = false;
        if (vehicle player == player) then {
            [objNull, player, rSwitchMove,""] call RE;
            player playActionNow "stop";
        };
        cutText [(localize "str_epoch_player_93"), "PLAIN DOWN"];
    };
            
} else {
    cutText [format[(localize "str_epoch_player_167"),_namePart], "PLAIN DOWN"];
};

{dayz_myCursorTarget removeAction _x} count s_player_repairActions;s_player_repairActions = [];
dayz_myCursorTarget = objNull;

//check if repaired fully
_hitpoints = _vehicle call vehicle_getHitpoints;
_allFixed = true;
{
    _damage = [_vehicle,_x] call object_getHit;
    if (_damage > 0) exitWith {
        _allFixed = false;
    };
} count _hitpoints;

//update if repaired
if (_allFixed) then {
    _vehicle setDamage 0;
    //["PVDZE_veh_Update",[_vehicle,"repair"]] call callRpcProcedure;
    PVDZE_veh_SFix = [_vehicle,_selection,0];
    publicVariable "PVDZE_veh_SFix";
    if (local _vehicle) then {
        PVDZE_veh_SFix call object_setFixServer;
    };
};

s_player_repair_crtl = -1;

DZE_ActionInProgress = false;

5) В вашем dayz_server.pbo открываем файл server_monitor.sqf и находим там такие строки:

if (_selection in dayZ_explosiveParts && _dam > 0.8) then {_dam = 0.8};
                    [_object,_selection,_dam] call object_setFixServer;

и заменяем их этими:

                    if (_selection in Ori_VehicleUpgrades) then {
                        _object animate [_selection,_dam];
                        _object setVariable [_selection,_dam,true];
                    } else {    
                        if (_selection in dayZ_explosiveParts and _dam > 0.8) then {_dam = 0.8};
                        [_object,_selection,_dam] call object_setFixServer;
                    };

6) Открываем файл server_updateObject.sqf, находим там секцию _object_damage = { ...}; и все действия что описаны в этом пункте - выполняет ТОЛЬКО в этой секции

Находим этот код:

_selection = getText (configFile >> "CfgVehicles" >> (typeOf _object) >> "HitPoints" >> _x >> "name");

и сразу после него добавляем это:

if (_selection in Ori_VehicleUpgrades) then {_dam = 0;}; //prevent double writtings

А после этого кода:
```
} count _hitpoints;
```

Добавляем этот:

        if (typeOf _object in Ori_VehiclesList) then {
        _cfg = configFile >> "CfgVehicles" >> (typeOf _object) >> "AnimationSources";
        _tc = count _cfg;
                for "_mti" from 0 to _tc-1 do {
                _mt = (_cfg select _mti);
                _st = getText(_mt >> "source");
                if (_st in Ori_VehicleUpgrades) then {
                _hit = _object getVariable [_st,1];
                _object animate [_st,_hit];
                _array set [count _array,[_st,_hit]];


                };
            };
        };

7) Открываем файл server_publishVehicle.sqf и ищем это:

_selection = getText(configFile >> "cfgVehicles" >> _class >> "HitPoints" >> _x >> "name");

и сразу после него добавляем этот код:

if (_selection in Ori_VehicleUpgrades) then {_dam = 0;}; //prevent double writtings

8) Ищем этот код:

} count _hitpoints;

добавляем после него:

        if (typeOf _object in Ori_VehiclesList) then {
        _cfg = configFile >> "CfgVehicles" >> _class >> "AnimationSources";
        _tc = count _cfg;
                for "_mti" from 0 to _tc-1 do {
                _mt = (_cfg select _mti);
                _st = getText(_mt >> "source");
                if (_st in Ori_VehicleUpgrades) then {
                _hit = 1;
                _object setVariable [_st,_hit,true];
                _object animate [_st,_hit];
                _array set [count _array,[_st,_hit]];

                };
            };
        };

9) Добавьте машины из мода Origins в dynamic_vehicles.sqf что бы они появлялись на карте.

["ori_ScrapBuggy",3],["ori_survivorBus",3],["ori_vil_lada_2105_rust",3],["ori_poldek_black",3],["ori_poldek",3],["ori_rth_originsmod_bathmobile",3],["ori_transit",3],["ori_vil_originsmod_lublin_truck",3],["ori_vil_originsmod_truck_civ",3],["ori_vil_originsmod_truck_civ",3],["ori_originsmod_pickupoldfuel",3],["ori_p85_originsmod_cucv_pickup",3],["ori_originsmod_pickupold",3]

Данный гайд изначально был совсем "не дружелюбный" к новичкам, но я постарался упростить его в рамках разумного (которые были определены мной в начале поста). Надеюсь что я вам помог. Ставим плюсы и развлекаемся!

Оригинал статьи:

http://epochmod.com/forum/index.php?/topic/34690-release-origins-vehicle-upgrades/

hekut144 · 5 июля 2015

Прошу помощи не появляется пункт в меню, смотрю на транспорт из ориджинса старый, тулбокс и запчасти есть, использую епоч 1.0.5.1 и ориджинс 1.7.9.5, путь к скрипту в fn_selfActions.sqf верный

Изменено 5 июля 2015 пользователем hekut144 (история изменений)

DimitriPokki · 5 июля 2015

Прошу помощи не появляется пункт в меню, смотрю на транспорт из ориджинса старый, тулбокс и запчасти есть, использую епоч 1.0.5.1 и ориджинс 1.7.9.5, путь к скрипту в fn_selfActions.sqf верный

Криво указали Ori_VehiclesList

hekut144 · 5 июля 2015

Ori_VehiclesList имеется в variables.sqf

DimitriPokki · 5 июля 2015

Проверь все хорошо. Желательно чекни рпт сервера и клиента.

hekut144 · 5 июля 2015

3-ий раз заново установил скрипт, 1 раз остюда, 2-ой раз с американского сайта, 3-ий раз отсюда, так вот, в скролл меню пункта все так же нет, в логах ничего такого нет.

ArmA2OAServer.RPT - http://pastebin.com/rB8XmyKT
ArmA2OA.RPT - http://pastebin.com/540ePhLe
Файлы чистые (производил 1 запуск с ними, открывал лишь скрол меню)

hekut144 · 6 июля 2015

Вообщем на забугорном форуме говорят мол не работает с 1.7.9.5 лишь 1.7.9, мне кажется бред, т.к. элементарно пункт из селфэкшона не показывается

hekut144 · 31 августа 2015

Анимации бронирования не изменились, лично проверил, броню своим скриптом нанести могу, тут по прежнему нет пунктов в меню, прошу помощи

BIG_MONSTR · 31 августа 2015

У меня вопрос, может не по теме но прошу помощи некоторая техника с мода оригинс 1.7.9.5 не работает невозможно в неё сесть и надпись в воздухе весит ORIGINS (запарожец, бека и так далее), работает только с мода 1.7.9

hekut144 · 31 августа 2015

Есть фикс, сейчас дам, пару строк нужно добавить в server_monitor.sqf: (работает с техникой при покупке, спавне сервером, при спавне через админку заработает после рестарта, при наличии фикса, сам фикс убирает лого и дает возможность пользоваться ей (техникой))

_oriarray =["ori_ZAZ968M","ori_taviander","ori_buchanka","ori_m3","ori_maniac","ori_KaTransp","ori_ScrapRaft"];

if (typeOF _object in _oriarray) then {

_object animate ["tropa",1];

if (typeOF _object == "ori_ScrapRaft") then {_object animate ["OriModOhrana",1];};

};

Добавь выше:

_lockable = 0;

if(isNumber (configFile >> "CfgVehicles" >> _type >> "lockable")) then {

_lockable = getNumber(configFile >> "CfgVehicles" >> _type >> "lockable");

};

Товарищи знатоки, помогите пожалуйста с бронированием

Изменено 31 августа 2015 пользователем hekut144 (история изменений)

BIG_MONSTR · 31 августа 2015

Есть фикс, сейчас дам, пару строк нужно добавить в server_monitor.sqf: (работает с техникой при покупке, спавне сервером, при спавне через админку заработает после рестарта, при наличии фикса, сам фикс убирает лого и дает возможность пользоваться ей (техникой))

_oriarray =["ori_ZAZ968M","ori_taviander","ori_buchanka","ori_m3","ori_maniac","ori_KaTransp","ori_ScrapRaft"];

if (typeOF _object in _oriarray) then {

_object animate ["tropa",1];

if (typeOF _object == "ori_ScrapRaft") then {_object animate ["OriModOhrana",1];};

};



Добавь выше:

_lockable = 0;

            if(isNumber (configFile >> "CfgVehicles" >> _type >> "lockable")) then {

                _lockable = getNumber(configFile >> "CfgVehicles" >> _type >> "lockable");

            };

Товарищи знатоки, помогите пожалуйста с бронированием

Все конечно хорошо вот если бы он сразу работал а не после рестарта было бы супер))) но все равно спс лови+

hekut144 · 31 августа 2015

Так добавь в торговлю транспорт и динамический спавн, там все отлично работает, и есть фикс для админки (admin tool или tools для инфи не находил), это у меня предположение есть почему не работает данный скрипт, тут один оператор по моему не закрыт (возможно)

if (_statuss == 1) then {

только не знаю где именно их закрыть, хотя нет

Изменено 31 августа 2015 пользователем hekut144 (история изменений)

BIG_MONSTR · 1 сентября 2015

Так добавь в торговлю транспорт и динамический спавн, там все отлично работает, и есть фикс для админки (admin tool или tools для инфи не находил), это у меня предположение есть почему не работает данный скрипт, тут один оператор по моему не закрыт (возможно)
if (_statuss == 1) then {
 
только не знаю где именно их закрыть, хотя нет

я добавлял к торговцам они так и остались с лого и не работали а вот спам да

hekut144 · 1 сентября 2015

У меня и спавн и покупка без лого

hekut144 · 1 сентября 2015

Может быть еще нужно в какой нибудь trade_any_vehicle.sqf воткнуть или где там спавн техники происходит

BIG_MONSTR · 1 сентября 2015

Может быть еще нужно в какой нибудь trade_any_vehicle.sqf воткнуть или где там спавн техники происходит

Ты свой выложи trade_any_vehicle.sqf

hekut144 · 1 сентября 2015

Там у меня пусто (в смысле нету скрипта анимации скрытия логотипа), и стоит система койнов, возможно у тебя нет

Вот доказательсво что бронирование работает на 1.7.9.5 весии, я написал скрипт, вот только не сохраняется при рестарте

server_publishVehicle2.sqf и server_publishVehicle3.sqf вот туда почти в самый низ засунь код который я тебе дал

После данных строк

diag_log ("PUBLISH: " + str(_activatingPlayer) + " Bought " + (_class) + " with ID " + str(_uid));

diag_log ("PUBLISH: " + str(_activatingPlayer) + " Upgraded " + (_class) + " with ID " + str(_uid));

одна из одного файла вторая из другого

и с покупкой все отлично будет

Изменено 1 сентября 2015 пользователем hekut144 (история изменений)

BIG_MONSTR · 1 сентября 2015

Там у меня пусто (в смысле нету скрипта анимации скрытия логотипа), и стоит система койнов, возможно у тебя нет

Вот доказательсво что бронирование работает на 1.7.9.5 весии, я написал скрипт, вот только не сохраняется при рестарте

server_publishVehicle2.sqf и server_publishVehicle3.sqf вот туда почти в самый низ засунь код который я тебе дал

После данных строк

diag_log ("PUBLISH: " + str(_activatingPlayer) + " Bought " + (_class) + " with ID " + str(_uid));

diag_log ("PUBLISH: " + str(_activatingPlayer) + " Upgraded " + (_class) + " with ID " + str(_uid));

одна из одного файла вторая из другого

и с покупкой все отлично будет

ок спс тебе большое, попробую, я вот смотрю у тебя где верт стоит эта вышка раскрывается, есть скрипт на нее?, просто у меня есть и дома и крепость а вот этого чуда нету, все искал, а тут бах и у тебя есть)))) если поделишься буду благодарен

hekut144 · 1 сентября 2015

Она у тебя есть, называется elektro elektro2 elektro3 (бандит) elektro_hero elektro2_hero elektro3_hero (герой), открытие ее (крышки 3-го яруса) я сам писал, держи:

animate ['svich',1];

animate ['heli1',1];

animate ['heli2',1];

animate ['heli3',1];

animate ['heli4',1];

animate ['heli5',1];

animate ['heli6',1];

animate ['heli7',1];

animate ['heli8',1];

1 открытие 0 закрытие

Есть еще у меня скрипт прилипания к вышке (лепке) да вот только его со стройкой связать не могу, вот 4 дома полностью сделал

Изменено 1 сентября 2015 пользователем hekut144 (история изменений)

BIG_MONSTR · 2 сентября 2015

Она у тебя есть, называется elektro elektro2 elektro3 (бандит) elektro_hero elektro2_hero elektro3_hero (герой), открытие ее (крышки 3-го яруса) я сам писал, держи:

animate ['svich',1];

animate ['heli1',1];

animate ['heli2',1];

animate ['heli3',1];

animate ['heli4',1];

animate ['heli5',1];

animate ['heli6',1];

animate ['heli7',1];

animate ['heli8',1];

1 открытие 0 закрытие

Есть еще у меня скрипт прилипания к вышке (лепке) да вот только его со стройкой связать не могу, вот 4 дома полностью сделал

Я знаю что они у меня есть просто я не мог их заставить работать электро они у меня в кравте а вот это чудо...)) я попробую конечно то что дал, но я в скриптах не так силен я беру готовые скрипты и под себя их переделываю, ты меня направь в нужное русло что и как делать, я предполагаю понадобятся (fn_selfActions.sqf и надо создать два файла OPEN и CLOSE в них вписать сам код) а вот как это реализовать это мне не понятно, есть конечно некоторые соображение но... и на счет прилипание очень интересно, и еще вопрос если у тебя есть Крепость то как ты реализовал работу, у меня после установки самой крепости она начинает работать после рестарта, там где я это брал говорят что типо нет фикса, ну я и смерился, если нет то нет это так, не очень важно))

hekut144 · 2 сентября 2015

У меня есть и работает все с последней версии ориджинс мода, кроме кпк и аптечек, выбора скинов в крепости, кпк и миссии они тупо статичные, аптечки свои сделаю лишь только не знаю как их в интерефейсе воткнуть, сделаю предмет в который складывать можно будет, скины пакетами сделаю, когда соединю прилипалку со стройкой гнезда выложу в сеть, да верно, нужно в меню действий добавить условие если ты смотришь на гнездо и ты овнер исполнение скрипта

BIG_MONSTR · 2 сентября 2015

У меня есть и работает все с последней версии ориджинс мода, кроме кпк и аптечек, выбора скинов в крепости, кпк и миссии они тупо статичные, аптечки свои сделаю лишь только не знаю как их в интерефейсе воткнуть, сделаю предмет в который складывать можно будет, скины пакетами сделаю, когда соединю прилипалку со стройкой гнезда выложу в сеть, да верно, нужно в меню действий добавить условие если ты смотришь на гнездо и ты овнер исполнение скрипта

СПС большое тебе, буду пробывать.

hekut144 · 2 сентября 2015

Нашел я чертову проблему с бронированием, косяк действительно в меню действий!!!

Изменено 2 сентября 2015 пользователем hekut144 (история изменений)

BIG_MONSTR · 2 сентября 2015

Нашел я чертову проблему с бронированием, косяк действительно в меню действий!!!

Поделись)), и спосибо тебе за Fix ща норм все с покупкой, а вот с ромашкой (elektro3) ни как((

Изменено 2 сентября 2015 пользователем BIG_MONSTR (история изменений)

hekut144 · 2 сентября 2015

Я сам парился долго, хотя там делов на 2 минуты

Войти

Объявления

⚙️ Новые онлайн-инструменты для DayZ 26.07.2026

Скрипт Улучшения\апгрейд машин из Origins в DayZ EPOCH

Рекомендованные сообщения

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах

Поделиться сообщением

Ссылка на сообщение

Поделиться на других сайтах