Не работает велосипед из тулбокса.

Делал велосипед из тулбокса вот по этому гайду http://epochmod.ru/forum/index.php?/topic/87-reliz-uluchshennoe-razvertyvanie-avtomobilia-s-o/

В итоге появляется велосипед но исчезает секунд через 20.

Если не ставить файлы из архива велосипед не исчезает,но его можно делать бесконечно и без запчастей.В чем может быть проблема?

Изменено 24 февраля 2015 пользователем Nyborezik (история изменений)

EVD_deploy.sqf

/*
	Enhanced Vehicle Deployment by TheFarix
*/

call compile preprocessFileLineNumbers "ZSC\addons\EVD\EVD_common.sqf";

if (dayz_combat == 1) exitwith { cutText ["\n\nНельзя делать это действие во время боя!", "PLAIN DOWN"] };

private ["_type","_inVehicle","_onLadder","_canDo","_materials","_proceed","_qty","_missing","_missingQty","_objectID"];

_type = _this select 0;

_inVehicle = (vehicle player != player);
_onLadder =	(getNumber (configFile >> "CfgMovesMaleSdr" >> "States" >> (animationState player) >> "onLadder")) == 1;
_canDo = (!r_drag_sqf and !r_player_unconscious and !_onLadder and !_inVehicle);

if (_canDo) then {
	_materials = [_type] call EVDGetMaterials;

	// Dry run to see if all parts are available.
	_proceed = true;
	if (count _materials > 0) then {
		{
			_itemIn = _x select 0;
			_countIn = _x select 1;
		
			_qty = { _x == _itemIn } count magazines player;

			if(_qty < _countIn) exitWith { _missing = _itemIn; _missingQty = (_countIn - _qty); _proceed = false; };
		} forEach _materials;
	};

	if (_proceed) then {
		closeDialog 1;

		cutText ["\n\nКрафт велосипеда начат", "PLAIN DOWN"];

		[1,1] call dayz_HungerThirst;
		player playActionNow "Medic";
        player removeWeapon "ItemToolbox";
		
		[player,"repair",0,false] call dayz_zombieSpeak;
		[player,50,true,(getPosATL player)] spawn player_alertZombies;

		r_interrupt = false;
		_animState = animationState player;
		r_doLoop = true;
		_started = false;
		_finished = false;

		while {r_doLoop} do {
			_animState = animationState player;
			_isMedic = ["medic",_animState] call fnc_inString;
			if (_isMedic) then {
				_started = true;
			};
			if (_started and !_isMedic) then {
				r_doLoop = false;
				_finished = true;
			};
			if (r_interrupt) then {
				r_doLoop = false;
			};
			sleep 0.1;
		};
		r_doLoop = false;

		if (_finished) then {
			_removed_total = 0; // count total of removed items
			_tobe_removed_total = 0; // count total of all to be removed items
			// Take items
			{
				_removed = 0;
				_itemIn = _x select 0;
				_countIn = _x select 1;
				_tobe_removed_total = _tobe_removed_total + _countIn;

				{
					_configParent = configName(inheritsFrom(configFile >> "cfgMagazines" >> _x));
					if( (_removed < _countIn) && ((_x == _itemIn) || (_configParent == _itemIn))) then {
						_num_removed = ([player,_x] call BIS_fnc_invRemove);
						_removed = _removed + _num_removed;
						_removed_total = _removed_total + _num_removed;
						if(_num_removed >= 1) then {
							_temp_removed_array set [count _temp_removed_array,_x];
						};
					};

				} forEach magazines player;

			} forEach _materials;
		
			// Only proceed if all parts were removed successfully
			if(_removed_total == _tobe_removed_total) then {
				if (EVDSellVehicles) then {
					_objectID = str(round(random 999999));
				} else {
					_objectID = "0";
				};

				_object = _type createVehicle (position player);
				_object setVariable ["ObjectID", _objectID, true];
				_object setVariable ["ObjectUID", _objectID, true];
				_object addEventHandler ["GetIn",{
					_nil = [nil,(_this select 2),"loc",rTITLETEXT,"ПРЕДУПРЕЖДЕНИЕ: Это техника исчезнит полсе рестарта!","PLAIN DOWN",5] call RE;
				}];

				clearWeaponCargoGlobal _object;
				clearMagazineCargoGlobal _object;
				_object setVehicleAmmo 0;

				player reveal _object;

				cutText ["\n\nВы создали велосипед!", "PLAIN DOWN"];
			} else {
				// Refund parts since we failed
				{player addMagazine _x;} forEach _temp_removed_array;

				cutText [format[(localize "str_epoch_player_151"),_removed_total,_tobe_removed_total], "PLAIN DOWN"];
			};
		} else {
			r_interrupt = false;
			player switchMove "";
			player playActionNow "stop";
			cutText ["\n\nCanceled deploying vehicle", "PLAIN DOWN"];
		};
	} else {
		_textMissing = getText(configFile >> "CfgMagazines" >> _missing >> "displayName");
		cutText [format["Missing %1 more of %2",_missingQty, _textMissing], "PLAIN DOWN"];
	};
} else {
	cutText ["\n\nКрафт велосипеда отменен", "PLAIN DOWN"];
}; 

 

EVD_pack.sqf

/*
	Enhanced Vehicle Deployment by TheFarix
*/

call compile preprocessFileLineNumbers "ZSC\addons\EVD\EVD_common.sqf";

if (dayz_combat == 1) exitwith { cutText ["\n\nНельзя делать это действие во время боя!", "PLAIN DOWN"] };

private ["_obj","_animState","_started","_finished"];

if(DZE_ActionInProgress) exitWith { cutText ["Запаковка велосипеда в действий." , "PLAIN DOWN"]; };
DZE_ActionInProgress = true;

player removeAction s_player_packVehicle;
s_player_packVehicle = 1;

_obj = _this select 3;

cutText ["Запаковка начата", "PLAIN DOWN"];

[1,1] call dayz_HungerThirst;
player playActionNow "Medic";
player addWeapon "ItemToolbox";

[player,"repair",0,false] call dayz_zombieSpeak;
[player,50,true,(getPosATL player)] spawn player_alertZombies;

r_interrupt = false;
_animState = animationState player;
r_doLoop = true;
_started = false;
_finished = false;

while {r_doLoop} do {
	_animState = animationState player;
	_isMedic = ["medic",_animState] call fnc_inString;
	if (_isMedic) then {
		_started = true;
	};
	if (_started and !_isMedic) then {
		r_doLoop = false;
		_finished = true;
	};
	if (r_interrupt) then {
		r_doLoop = false;
	};
	sleep 0.1;
};
r_doLoop = false;
		
if (_finished) then {
	// Double check that object is not null
	if(!isNull(_obj)) then {
		_ipos = getPosATL _obj;
		_type = typeOf _obj;

		_materials = [_type] call EVDGetMaterials;

		//Delete from hive
		_objectID  = _obj getVariable ["ObjectID","0"];
		_objectUID = _obj getVariable ["ObjectUID","0"];
		_activatingPlayer = player;
		PVDZE_obj_Delete = [_objectID,_objectUID,_activatingPlayer];
		publicVariableServer "PVDZE_obj_Delete";

		deleteVehicle _obj;

		if (_ipos select 2 < 0) then {
			_ipos set [2,0];
		};

		_radius = 1;

		// give refund items
		if((count _materials) > 0) then {
			_item = createVehicle ["WeaponHolder", _iPos, [], _radius, "CAN_COLLIDE"];
			{
				_itemOut = _x select 0;
				_countOut = _x select 1;
				if (typeName _countOut == "ARRAY") then {
					_countOut = round((random (_countOut select 1)) + (_countOut select 0));
				};
				_item addMagazineCargoGlobal [_itemOut,_countOut];
			} forEach _materials;

			_item setposATL _iPos;

			player reveal _item;

			player action ["Gear", _item];
		};
	} else {
		cutText [(localize "str_epoch_player_91"), "PLAIN DOWN"];
	};
} else {
	r_interrupt = false;
	player switchMove "";
	player playActionNow "stop";
	cutText ["Запаковка отменено", "PLAIN DOWN"];
};

DZE_ActionInProgress = false;
s_player_packVehicle = -1;
 

 

EVD_common.sqf

/*
	Enhanced Vehicle Deployment by TheFarix
*/

//////////////////////////////////////////////////////////////////////////////////////////
//                                     Configuration                                    //
//////////////////////////////////////////////////////////////////////////////////////////

// Do you want vehicles to be sold at traders?
EVDSellVehicles = true;

//////////////////////////////////////////////////////////////////////////////////////////
//                                   Common Functions                                   //
//////////////////////////////////////////////////////////////////////////////////////////
EVDGetMaterials = {
	private ["_type","_materials"];

	_type = _this select 0;

	switch (_type) do {
		case "MMT_Civ":		{ _materials = []; };
	};

	_materials;
};

В конец fn_selfActions.sqf

 

//Pack Vehicles
	if (_typeOfCursorTarget in EVDVehicleArray and !(locked _cursorTarget) and (damage _cursorTarget < 2)) then {
		if (s_player_packvehicle < 0) then {
			s_player_packvehicle = player addAction ["Запаковать велосипед", "ZSC\addons\EVD\EVD_pack.sqf",_cursorTarget, 0, false, true, "",""];
		};
	} else {
		player removeAction s_player_packvehicle;
		s_player_packvehicle = -1;
	};
//End pach

В конец variables
 

EVDVehicleArray = ["MMT_Civ"];
dayz_allowedObjects = dayz_allowedObjects + EVDVehicleArray;

if(isServer) then {
	DZE_safeVehicle = DZE_safeVehicle + EVDVehicleArray;
};

P.S Пути конечно под себя менять 

Изменено 24 февраля 2015 пользователем Dimitri (история изменений)

Variables не прописан.

Variables не прописан.

Подробнее!!! Я создал файл variables и скопировал туда

EVDVehicleArray = ["MMT_Civ","TT650_Civ","CSJ_GyroC"];

dayz_allowedObjects = dayz_allowedObjects + EVDVehicleArray;

 

if(isServer) then {

    DZE_safeVehicle = DZE_safeVehicle + EVDVehicleArray;

};

   DZE_safeVehicle = DZE_safeVehicle + EVDVehicleArray;

Вот это не совсем качественно работает.
По стариночке все нормально.
 

 

DZE_safeVehicle = ["MMT_Civ","TT650_Civ","CSJ_GyroC","ParachuteWest","ParachuteC"];
 

 

   DZE_safeVehicle = DZE_safeVehicle + EVDVehicleArray;

 

Вот это не совсем качественно работает.

По стариночке все нормально.

 

 

DZE_safeVehicle = ["MMT_Civ","TT650_Civ","CSJ_GyroC","ParachuteWest","ParachuteC"];
 

Я сегодня днем так прописывал) не помогло,но в принципе щас еще разок попробую,отпишусь

Я уже дал ответ по данный вопрос ищите на форуме так трудно ?
http://s-platoon.ru/index.php?/topic/1788-sborka-transporta-pri-pomoschi-pkm-na-toolbox-enhanced-vehicle-deployment/?p=19446
Или 
http://s-platoon.ru/index.php?/topic/2176-infistar-banit/

Я уже дал ответ по данный вопрос ищите на форуме так трудно ?

http://s-platoon.ru/index.php?/topic/1788-sborka-transporta-pri-pomoschi-pkm-na-toolbox-enhanced-vehicle-deployment/?p=19446

Или 

http://s-platoon.ru/index.php?/topic/2176-infistar-banit/

Спасибо друг!Помогло! Еще такой вопрос.Как изменить скрипт чтоб для крафта нужен был только тулбокс и чтобы он исчезал после создания вела,а то когда прописываюю вместо запчастей тулбокс,он не хочет крафтить.

Спасибо!Все работает.

Изменено 25 февраля 2015 пользователем Nyborezik (история изменений)

Здравствуйте, облазил весь сайт не могу найти файлик (велик из тулбокса) с сервером начал недавно работать, но архива так и не нашел скиньте пожалуйста. Заранее спасибо

Здравствуйте, облазил весь сайт не могу найти файлик (велик из тулбокса) с сервером начал недавно работать, но архива так и не нашел скиньте пожалуйста. Заранее спасибо

Нажми на ссылку в самом начале моего вопроса.Пролистай гайд до 8 пункта и под ним нажми на кнопку скачать.

Или в принципе они тебе не нужны!!! Делай все по гайду,а потом вернись в эту тему.И создай 3 файлика и скопируй в них все то что писал Дмитрий!

Изменено 25 февраля 2015 пользователем Nyborezik (история изменений)

Нажми на ссылку в самом начале моего вопроса.Пролистай гайд до 8 пункта и под ним нажми на кнопку скачать.

Или в принципе они тебе не нужны!!! Делай все по гайду,а потом вернись в эту тему.И создай 3 файлика и скопируй в них все то что писал Дмитрий!

Спасибо дома попробую и еще вопрос где лучше разместить evd файлы?

Спасибо дома попробую и еще вопрос где лучше разместить evd файлы?

У меня они хранятся в папке custom\EVD\EVD_common и т.д.

Если не получиться позвони в скайп) Я вроде как в профиле указал его =)

Изменено 25 февраля 2015 пользователем Nyborezik (история изменений)

Всем сдрасте, подскажите вот у меня спавные машины чинятся с помощью одного тулбокса, тоесть даже запчасти им не нужны! можно ли как то это исправить?

У меня миссионные так чинятся. ХЗ почему.