Ошибки в RPT

Добрый день всем, помогите исправить ошибки в RPT логах.

1. Ошибка в arma2oaserver.RPT:

if(_isNormal)then {
_inventory = [
getWeapo>
19:52:06 Error position: <_isNormal)then {
_inventory = [
getWeapo>
19:52:06 Error Undefined variable in expression: _isnormal
19:52:06 File z\addons\dayz_server\compile\server_updateObject.sqf, line 72
19:52:06 Error in expression };

Ошибка появилась после установки DoorManagement от Zupa. В секцию private добавил переменную, не помогло.

Файл server_updateObject.sqf:

/*
[_object,_type] spawn server_updateObject;
*/
private ["_object","_type","_objectID","_uid","_lastUpdate","_needUpdate","_object_position","_object_inventory","_object_damage","_isNotOk","_parachuteWest","_firstTime","_object_killed","_object_repair","_isbuildable","_hit","_inventory","_isNormal"];

_object = _this select 0;

if(isNull(_object)) exitWith {
diag_log format["Skipping Null Object: %1", _object];
};

_type = _this select 1;
_parachuteWest = ((typeOf _object == "ParachuteWest") || (typeOf _object == "ParachuteC"));
_isbuildable = (typeOf _object) in dayz_allowedObjects;
_isNotOk = false;
_firstTime = false;

_objectID = _object getVariable ["ObjectID","0"];
_uid = _object getVariable ["ObjectUID","0"];

if ((typeName _objectID != "string") || (typeName _uid != "string")) then
{
diag_log(format["Non-string Object: ID %1 UID %2", _objectID, _uid]);
//force fail
_objectID = "0";
_uid = "0";
};
if (!_parachuteWest && !(locked _object)) then {
if (_objectID == "0" && _uid == "0") then
{
_object_position = getPosATL _object;
_isNotOk = true;
};
};

// do not update if buildable && not ok
if (_isNotOk && _isbuildable) exitWith { };

// delete if still not ok
//if (_isNotOk) exitWith { deleteVehicle _object; diag_log(format["Deleting object %1 with invalid ID at pos [%2,%3,%4]",typeOf _object,_object_position select 0,_object_position select 1, _object_position select 2]); };


_lastUpdate = _object getVariable ["lastUpdate",time];
_needUpdate = _object in needUpdate_objects;

// TODO ----------------------
_object_position = {
private["_position","_worldspace","_fuel","_key"];
_position = getPosATL _object;
_worldspace = [getDir _object, _position] call AN_fnc_formatWorldspace;
_fuel = 0;
if (_object isKindOf "AllVehicles") then {
_fuel = fuel _object;
};
_key = format["CHILD:305:%1:%2:%3:",_objectID,_worldspace,_fuel];
//diag_log ("HIVE: WRITE: "+ str(_key));
_key call server_hiveWrite;
};

_object_inventory = {
private["_inventory","_previous","_key"];
isNormal = true;
if (typeOf (_object) == "Plastic_Pole_EP1_DZ") then{
_isNormal = false;
_inventory = _object getVariable ["plotfriends", []]; //We're replacing the inventory with UIDs for this item
};
if (typeOf (_object)in DZE_DoorsLocked) then{
_isNormal = false;
_inventory = _object getVariable ["doorfriends", []]; //We're replacing the inventory with UIDs for this item
};

if(_isNormal)then {
_inventory = [
getWeaponCargo _object,
getMagazineCargo _object,
getBackpackCargo _object,
_object getVariable["bankMoney",0]
];
};
_previous = str(_object getVariable["lastInventory",[]]);
if (str(_inventory) != _previous) then {
if(alive _object) then{
_object setVariable["lastInventory",_inventory];
};
if (_objectID == "0") then {
_key = format["CHILD:309:%1:%2:",_uid,_inventory];
} else {
_key = format["CHILD:303:%1:%2:",_objectID,_inventory];
};
//diag_log ("HIVE: WRITE: "+ str(_key));
_key call server_hiveWrite;
};
};

_object_damage = {
private["_hitpoints","_array","_hit","_selection","_key","_damage"];
_hitpoints = _object call vehicle_getHitpoints;
_damage = damage _object;
_array = [];
{
_hit = [_object,_x] call object_getHit;
_selection = getText (configFile >> "CfgVehicles" >> (typeOf _object) >> "HitPoints" >> _x >> "name");
if (_hit > 0) then {_array set [count _array,[_selection,_hit]]};
_object setHit ["_selection", _hit];
} count _hitpoints;

_key = format["CHILD:306:%1:%2:%3:",_objectID,_array,_damage];
//diag_log ("HIVE: WRITE: "+ str(_key));
_key call server_hiveWrite;
_object setVariable ["needUpdate",false,true];
};

_object_killed = {
private["_hitpoints","_array","_hit","_selection","_key","_damage"];
if(_object isKindOf "AllVehicles") then{
_object execVM "\z\addons\dayz_server\compile\server_crashLoot.sqf";
};
_hitpoints = _object call vehicle_getHitpoints;
//_damage = damage _object;
_damage = 1;
_array = [];
{
_hit = [_object,_x] call object_getHit;
_selection = getText (configFile >> "CfgVehicles" >> (typeOf _object) >> "HitPoints" >> _x >> "name");
if (_hit > 0) then {_array set [count _array,[_selection,_hit]]};
_hit = 1;
_object setHit ["_selection", _hit];
} count _hitpoints;

if (_objectID == "0") then {
_key = format["CHILD:306:%1:%2:%3:",_uid,_array,_damage];
} else {
_key = format["CHILD:306:%1:%2:%3:",_objectID,_array,_damage];
};
//diag_log ("HIVE: WRITE: "+ str(_key));
_key call server_hiveWrite;
_object setVariable ["needUpdate",false,true];
if ((count _this) > 2) then {
_killer = _this select 2;
_charID = _object getVariable ['CharacterID','0'];
_objID = _object getVariable['ObjectID','0'];
_objUID = _object getVariable['ObjectUID','0'];
_worldSpace = getPosATL _object;
if (getPlayerUID _killer != "") then {
_name = if (alive _killer) then { name _killer; } else { format["OBJECT %1", _killer]; };
diag_log format["Vehicle killed: Vehicle %1 (TYPE: %2), CharacterID: %3, ObjectID: %4, ObjectUID: %5, Position: %6, Killer: %7 (UID: %8)", _object, (typeOf _object), _charID, _objID, _objUID, _worldSpace, _name, (getPlayerUID _killer)];
} else {
diag_log format["Vehicle killed: Vehicle %1 (TYPE: %2), CharacterID: %3, ObjectID: %4, ObjectUID: %5, Position: %6", _object, (typeOf _object), _charID, _objID, _objUID, _worldSpace];
};
};
};

_object_repair = {
private["_hitpoints","_array","_hit","_selection","_key","_damage"];
_hitpoints = _object call vehicle_getHitpoints;
_damage = damage _object;
_array = [];
{
_hit = [_object,_x] call object_getHit;
_selection = getText (configFile >> "CfgVehicles" >> (typeOf _object) >> "HitPoints" >> _x >> "name");
if (_hit > 0) then {_array set [count _array,[_selection,_hit]]};
_object setHit ["_selection", _hit];
} count _hitpoints;

_key = format["CHILD:306:%1:%2:%3:",_objectID,_array,_damage];
//diag_log ("HIVE: WRITE: "+ str(_key));
_key call server_hiveWrite;
_object setVariable ["needUpdate",false,true];
};
// TODO ----------------------

_object setVariable ["lastUpdate",time,true];
switch (_type) do {
case "all": {
call _object_position;
call _object_inventory;
call _object_damage;
};
case "position": {
if (!(_object in needUpdate_objects)) then {
//diag_log format["DEBUG Position: Added to NeedUpdate=%1",_object];
needUpdate_objects set [count needUpdate_objects, _object];
};
};
case "gear": {
call _object_inventory;
};
case "damage": {
if ( (time - _lastUpdate) > 5) then {
call _object_damage;
} else {
if (!(_object in needUpdate_objects)) then {
//diag_log format["DEBUG Damage: Added to NeedUpdate=%1",_object];
needUpdate_objects set [count needUpdate_objects, _object];
};
};
};
case "killed": {
call _object_killed;
};
case "repair": {
call _object_damage;
};
};

 

2.Ошибка в клиентском ArmA2OA.RPT:

Error in expression _passArray >
Error position: <_vector];
_passArray >
Error Undefined variable in expression: _vector
File mpmissions\__CUR_MP.Chernarus\Custom\A_Plot_for_Life\player_build_controls.sqf, line 220

Error in expression };
}>
Error position: <_vector] call player_build_publish;
};
}>
Error Undefined variable in expression: _vector
File mpmissions\__CUR_MP.Chernarus\Custom\A_Plot_for_Life\modular_build.sqf, line 90

,>

Ошибка появилась после установки DayzBuildVectors-master. В секции private переменная _vector уже была внесена, пробовал добавить в variables не помогло.

Файл player_build_controls.sqf:

private ["_canDo","_passArray","_objHDiff","_isOk","_zheightchanged","_zheightdirection","_rotate","_dir","_object","_position","_isAllowedUnderGround","_location1","_location2","_cancel","_reason","_lastDir","_objectHelper","_objectHelperDir","_objectHelperPos","_vector"];

_object = _this select 0;
_isAllowedUnderGround = _this select 1;
_location1 = _this select 2;
_objectHelper = _this select 3;

_passArray = [];

_objHDiff = 0;
_isOk = true;
_cancel = false;
_reason = "";
_dir = getDir player; //required to pass direction when building
helperDetach = false;
_canDo = (!r_drag_sqf and !r_player_unconscious);
_position = [_objectHelper] call FNC_GetPos;

while {_isOk} do {

_zheightchanged = false;
_zheightdirection = "";
_rotate = false;

if (DZE_Q) then {
DZE_Q = false;
_zheightdirection = "up";
_zheightchanged = true;
};
if (DZE_Z) then {
DZE_Z = false;
_zheightdirection = "down";
_zheightchanged = true;
};
if (DZE_Q_alt) then {
DZE_Q_alt = false;
_zheightdirection = "up_alt";
_zheightchanged = true;
};
if (DZE_Z_alt) then {
DZE_Z_alt = false;
_zheightdirection = "down_alt";
_zheightchanged = true;
};
if (DZE_Q_ctrl) then {
DZE_Q_ctrl = false;
_zheightdirection = "up_ctrl";
_zheightchanged = true;
};
if (DZE_Z_ctrl) then {
DZE_Z_ctrl = false;
_zheightdirection = "down_ctrl";
_zheightchanged = true;
};
if (DZE_4) then {
_rotate = true;
DZE_4 = false;
if(DZE_dirWithDegrees) then{
DZE_memDir = DZE_memDir - DZE_curDegree;
}else{
DZE_memDir = DZE_memDir - 45;
};

};
if (DZE_6) then {
_rotate = true;
DZE_6 = false;
if(DZE_dirWithDegrees) then{
DZE_memDir = DZE_memDir + DZE_curDegree;
}else{
DZE_memDir = DZE_memDir + 45;
};
};

if(DZE_updateVec) then{
[_objectHelper,[DZE_memForBack,DZE_memLeftRight,DZE_memDir]] call fnc_SetPitchBankYaw;
DZE_updateVec = false;
};

if (DZE_F and _canDo) then {
if (helperDetach) then {
_objectHelper attachTo [player];
DZE_memDir = DZE_memDir-(getDir player);
helperDetach = false;
[_objectHelper,[DZE_memForBack,DZE_memLeftRight,DZE_memDir]] call fnc_SetPitchBankYaw;
} else {
_objectHelperPos = getPosATL _objectHelper;
detach _objectHelper;
DZE_memDir = getDir _objectHelper;
[_objectHelper,[DZE_memForBack,DZE_memLeftRight,DZE_memDir]] call fnc_SetPitchBankYaw;
_objectHelper setPosATL _objectHelperPos;
_objectHelper setVelocity [0,0,0]; //fix sliding glitch
helperDetach = true;
};
DZE_F = false;
};

if(_rotate) then {
[_objectHelper,[DZE_memForBack,DZE_memLeftRight,DZE_memDir]] call fnc_SetPitchBankYaw;
};

if(_zheightchanged) then {
if (!helperDetach) then {
detach _objectHelper;
_objectHelperDir = getDir _objectHelper;
};

_position = [_objectHelper] call FNC_GetPos;

if(_zheightdirection == "up") then {
_position set [2,((_position select 2)+0.1)];
_objHDiff = _objHDiff + 0.1;
};
if(_zheightdirection == "down") then {
_position set [2,((_position select 2)-0.1)];
_objHDiff = _objHDiff - 0.1;
};

if(_zheightdirection == "up_alt") then {
_position set [2,((_position select 2)+1)];
_objHDiff = _objHDiff + 1;
};
if(_zheightdirection == "down_alt") then {
_position set [2,((_position select 2)-1)];
_objHDiff = _objHDiff - 1;
};

if(_zheightdirection == "up_ctrl") then {
_position set [2,((_position select 2)+0.01)];
_objHDiff = _objHDiff + 0.01;
};
if(_zheightdirection == "down_ctrl") then {
_position set [2,((_position select 2)-0.01)];
_objHDiff = _objHDiff - 0.01;
};

if((_isAllowedUnderGround == 0) && ((_position select 2) < 0)) then {
_position set [2,0];
};

if (surfaceIsWater _position) then {
_objectHelper setPosASL _position;
} else {
_objectHelper setPosATL _position;
};

if (!helperDetach) then {
_objectHelper attachTo [player];
};
[_objectHelper,[DZE_memForBack,DZE_memLeftRight,DZE_memDir]] call fnc_SetPitchBankYaw;
};

sleep 0.5;

_location2 = [player] call FNC_GetPos;
_objectHelperPos = [_objectHelper] call FNC_GetPos;

if(DZE_5) exitWith {
_isOk = false;
_position = [_object] call FNC_GetPos;
detach _object;
_dir = getDir _object;
_vector = [(vectorDir _object),(vectorUp _object)];
deleteVehicle _object;
detach _objectHelper;
deleteVehicle _objectHelper;
};

if(_location1 distance _location2 > 10) exitWith {
_isOk = false;
_cancel = true;
_reason = "Вы отошли далеко от места, где вы начали строительство (в пределах 10 метров )";
detach _object;
deleteVehicle _object;
detach _objectHelper;
deleteVehicle _objectHelper;
};

if(_location1 distance _objectHelperPos > 10) exitWith {
_isOk = false;
_cancel = true;
_reason = "Объект находится далеко от места, где вы начали строить (в пределах 10 метров )";
detach _object;
deleteVehicle _object;
detach _objectHelper;
deleteVehicle _objectHelper;
};

if(abs(_objHDiff) > 10) exitWith {
_isOk = false;
_cancel = true;
_reason = "Нельзя передвигать вверх или вниз более чем на 10 метров";
detach _object;
deleteVehicle _object;
detach _objectHelper;
deleteVehicle _objectHelper;
};

if (player getVariable["combattimeout", 0] >= time) exitWith {
_isOk = false;
_cancel = true;
_reason = (localize "str_epoch_player_43");
detach _object;
deleteVehicle _object;
detach _objectHelper;
deleteVehicle _objectHelper;
};

if (DZE_cancelBuilding) exitWith {
_isOk = false;
_cancel = true;
_reason = "Cancelled building.";
detach _object;
deleteVehicle _object;
detach _objectHelper;
deleteVehicle _objectHelper;
};
};

_passArray = [_cancel,_reason,_position,_dir,_vector];
_passArray //[bool,string,array,int,array]

Файл modular_build.sqf:

//Check if building already in progress, exit if so.
if(DZE_ActionInProgress) exitWith { cutText [(localize "str_epoch_player_40") , "PLAIN DOWN"]; };
DZE_ActionInProgress = true;

private ["_itemConfig","_classname","_classnametmp","_require","_text","_ghost","_lockable","_requireplot","_isAllowedUnderGround","_offset","_isPole","_isLandFireDZ","_hasRequired","_hasrequireditem","_reason","_buildObject","_location1","_object","_objectHelper","_position","_controls","_cancel","_dir","_vector"];

/*Basic Defines*/
DZE_Q = false;
DZE_Z = false;

DZE_Q_alt = false;
DZE_Z_alt = false;

DZE_Q_ctrl = false;
DZE_Z_ctrl = false;

DZE_5 = false;
DZE_4 = false;
DZE_6 = false;

DZE_F = false;

DZE_cancelBuilding = false;

DZE_updateVec = false;
DZE_memDir = 0;
DZE_memForBack = 0;
DZE_memLeftRight = 0;

call gear_ui_init;
closeDialog 1;

DZE_buildItem = _this; //This is a magazine! It's global to allow access to it from outside functions

//count nearby objects. Returns [_cnt] number
[] call player_build_countNearby;

//Check illegal player states. Returns [_isFine] string
[] call player_build_states;

//check for nearby requirements (campfire, workshop, fueltank).
[] call player_build_needNearby;

//check config files and gather info about item (if using custom buildables, make your own similar function instead).
_itemConfig = [] call player_build_getConfig;

//define items collected from function
_classname = _itemConfig select 0; //string
_classnametmp = _itemConfig select 1; //string
_require = _itemConfig select 2; // array
_text = _itemConfig select 3; // string
_ghost = _itemConfig select 4; //string
_lockable = _itemConfig select 5; //int -- 0/1=No 2=lockbox, 3=combolock, 4=safe
_requireplot = _itemConfig select 6; //int
_isAllowedUnderGround = _itemConfig select 7; //int
_offset = _itemConfig select 8; //array
_isPole = _itemConfig select 9; //bool
_isLandFireDZ = _itemConfig select 10; //bool

//Check for nearby plotpoles. Returns [_IsNearPlot,_nearestPole,_ownerID,_friendlies] [int,Obj,int,array]
[_isPole, _requireplot, _isLandFireDZ] call player_build_plotCheck;

if (DZE_ActionInProgress) then { //needed otherwise _hasRequired gets RPT error

//Check for build requirements (missing tools and items). Returns [_hasrequireditem,_reason] [bool,string]
_hasRequired = [_require, _text, true, true] call player_build_buildReq;

//define item collected from function
_hasrequireditem = _hasRequired select 0; //bool

if (_hasrequireditem) then {
//Create object that is attached to a player (i.e Ghost preview if available)
_buildObject = [_classname, _ghost, _offset, true] call player_build_create;

//define items collected from function
_location1 = _buildObject select 0; //array
_object = _buildObject select 1; //Obj
_objectHelper = _buildObject select 2; //Obj

_controls = [_object, _isAllowedUnderGround, _location1, _objectHelper] call player_build_controls;

//define items collected from function
_cancel = _controls select 0; //bool
_reason = _controls select 1; //string
_position = _controls select 2; //array
_dir = _controls select 3; //int
_vector = _controls select 4; //array

//Publish item to a database
[_cancel, _position, _classnametmp,_isAllowedUnderGround, _text, _isPole, _lockable,_dir, _reason, _vector] call player_build_publish;
};
};

 

И ещё одна ошибка-загадка, появилась после установки A Plot for Life2.35+SnapPro1.4

Error in expression < };
};
};
};
_y = _this call oplayer_unlockDoor;
_y>
Error position: <= _this call oplayer_unlockDoor;
_y>
Error Generic error in expression

Ошибка появляется после открытия двери. Перелопатил все файлы из установочного пакета на предмет совпадений oplayer_unlockDoor и call oplayer_unlockDoor; и ни чего не нашёл. Надеялся что ошибка уйдёт после установки менеджера двери, но надежда не сбылась. При этом все двери открываются и закрываются.

 

PS. Установка производилась на чистый сервер в следующей последовательности:

A Plot for Life2.35+SnapPro1.4

DayzBuildVectors-master

Precise Base Building

PlotManagement

DoorManagement

Singlecurrency(Единая валюта и банк 4.0)

И другие скрипты к которым претензий нет.

 

PSS. С этими ошибками сервер запускается и работает, обьекты прилипают друг к другу как положено, векторы работают, двери открываются и закрываются, но хочется чтоб RPT были чистыми. 

1. Проверь регистр переменной везде должен быть один и тот же. 

Во 1

Внутри данной функции, с хераль она без подчеркивания - глобальная(3 строка)

 

_object_inventory = {
private["_inventory","_previous","_key"];
isNormal = true;
if (typeOf (_object) == "Plastic_Pole_EP1_DZ") then{
_isNormal = false;
_inventory = _object getVariable ["plotfriends", []]; //We're replacing the inventory with UIDs for this item
};

Во 2.

Данный код

 

if(_isNormal)then {
_inventory = [
getWeaponCargo _object,
getMagazineCargo _object,
getBackpackCargo _object,
_object getVariable["bankMoney",0]
];
};

вызывается по ходу выполнения скрипта, и до данной строки НЕТ вызова функции _object_inventory(да и других в которых фигурирует _isNormal), => переменная не определена, о чем тебе в РПТ и сообщается.

 

P.S.

1. Форматируйте нормально код, а не как на эпохе лежит. - Не надо юзать стандарты, т.к. будете путаться - где функция\массив начинается, и где заканчивается.

2. Запятые в массивах лучше ставить спереди - если код многострочный - так их хотябы видно, и видно если пропустили.

3. ВСЕ локальные функции и процедуры, переносите В САМЫЙ ВЕРХ скрипта, ДО исполняемого кода. Тогда не ошибетесь - был ли вызов, или нет.

Ну и делайте ИНИЦИАЛИЗАЦИЮ стартового значения переменных.

А так же вывод в РПТ, текущих значений, при отладке.

 

Если бы ты добавил -

diag_log(format["_isNormal, определен в хх строке, и сейчас равен: %1", _isNormal]);

и добавил бы данную строку в скрипт, во всех местах, где ее используешь - видел бы как минимум номер строки и значение, - any - т.е. - неопределенное - переменная не создана - и знал бы куда смотреть.

Во 1

Внутри данной функции, с хераль она без подчеркивания - глобальная(3 строка)

 

_object_inventory = {
private["_inventory","_previous","_key"];
isNormal = true;
if (typeOf (_object) == "Plastic_Pole_EP1_DZ") then{
_isNormal = false;
_inventory = _object getVariable ["plotfriends", []]; //We're replacing the inventory with UIDs for this item
};

Во 2.

Данный код

 

if(_isNormal)then {
_inventory = [
getWeaponCargo _object,
getMagazineCargo _object,
getBackpackCargo _object,
_object getVariable["bankMoney",0]
];
};

вызывается по ходу выполнения скрипта, и до данной строки НЕТ вызова функции _object_inventory(да и других в которых фигурирует _isNormal), => переменная не определена, о чем тебе в РПТ и сообщается.

 

P.S.

1. Форматируйте нормально код, а не как на эпохе лежит. - Не надо юзать стандарты, т.к. будете путаться - где функция\массив начинается, и где заканчивается.

2. Запятые в массивах лучше ставить спереди - если код многострочный - так их хотябы видно, и видно если пропустили.

3. ВСЕ локальные функции и процедуры, переносите В САМЫЙ ВЕРХ скрипта, ДО исполняемого кода. Тогда не ошибетесь - был ли вызов, или нет.

Ну и делайте ИНИЦИАЛИЗАЦИЮ стартового значения переменных.

А так же вывод в РПТ, текущих значений, при отладке.

 

Если бы ты добавил -

diag_log(format["_isNormal, определен в хх строке, и сейчас равен: %1", _isNormal]);

и добавил бы данную строку в скрипт, во всех местах, где ее используешь - видел бы как минимум номер строки и значение, - any - т.е. - неопределенное - переменная не создана - и знал бы куда смотреть.

Благодарю за подсказку, добавил подчёркивание перед переменной _isNormal и ошибка пропала.