JAEM | Эвакуационный вертолет

ZizionarD · July 29, 2021

Это обновленная версия JAEM от OtterNas3 для DayZ Epoch 1.0.7. Обновлена версия до ZSC и развернул все совместимое. ZSC можно использовать в качестве опции для оплаты создания эвакуационного вертолета, а действия Мудзерели по щелчку правой кнопкой мыши можно использовать для вызова эвакуационного вертолета.

Новые возможности:

Поддержка ZSC - вы можете выбрать валюту эпохи или ZSC для оплаты вашего эвакуационного вертолета.
Развертывание техники - вы можете использовать действия Mudzereli по щелчку правой кнопкой мыши для вызова эвакуационного вертолета вместо использования встроенного цикла самостоятельного действия.
Plot pole и plot friends - чтобы игроки не могли размещать вертолетные площадки для эвакуации в запрещенных местах, они должны строить их на своих собственных участках или на участках своих друзей.

Все переменные конфигурации размещены в файле variables.sqf. Все переменные имеют пояснительные комментарии. Настройте их в соответствии с вашими предпочтительными настройками:

// Evac Chopper Config Variables
evac_chopperPrice = 1; // This is the price players pay in full briefcases to set up an evac chopper (between 1-12 briefcases). Players must have the briefcases in their inventory.
evac_chopperUseZSC = false; // If you have ZSC installed you can set this to true and have players pay the amount below to set up an evac chopper.
evac_chopperPriceZSC = 100000; // Price for evac chopper if you have ZSC Installed and evac_chopperUseZSC set to true.
evac_chopperMinDistance = 500; // Minimum distance for player to call evac chopper. Do not set this lower than 500.
evac_chopperZoneMarker = 0; // Evac zone marker type (0 = Landingpad | 1 = Smoke).
evac_chopperNeedRadio = 0; // 1 - Require player to have a radio in gear to call evac chopper | 0 - Doesn't require radio to call evac chopper.
evac_chopperUseClickActions = false; // If you have Mudzereli's Deploy Anything installed and are going to use click actions to call the evac chopper, set this to true (disables call chopper self-action loop).

Инструкции по функциональности:

Если у вас есть какие-либо другие моды, которые сохраняют имя класса "HeliHRescue" в базе данных, имейте в виду, что это конкретное имя класса используется вместе с идентификатором владельца для работы этого мода.
Если у вас уже есть экземпляр HeliHRescue, сохраненный в базе данных с вашим идентификатором игрока, вы получите сообщение о том, что вы не можете создать другой экземпляр при попытке установить вертолет эвакуации.
Чтобы создать эвакуационный вертолет, вам нужен вертолет с ключом, столб для участка и деньги для покупки.
У вас должен быть ключ в вашем инвентаре, чтобы установить и очистить поле эвакуационный вертолет.
Подойдите к вертолету, и вы получите действия для настройки и очистки поля эвакуационного вертолета.
Вам не обязательно иметь при себе ключ, чтобы вызвать эвакуационный вертолет.
Существует монитор состояния полета, который отображается в том же месте, что и монитор отладки, поэтому для его просмотра вам потребуется отключить отладку.
Если вы используете действия по щелчку правой кнопкой мыши Mudzereli, обязательно установите переменную evac_chopperUseClickActions в значение true, чтобы отключить встроенный цикл самостоятельных действий.
Если ваш вертолет будет уничтожен, просто поместите новый на вертолетную площадку. Функция вызова эвакуационного вертолета находит ближайший вертолет (в пределах 10 метров) от вашей спасательной вертолетной площадки.
Деньги не возвращаются, когда вы отключаете эвакуационный вертолет.

Известные проблемы:

На данный момент известна только одна проблема. Если игрок будет убит во время полета эвакуационного вертолета, вертолет не вернется на базу. Пилот приземляется в зоне эвакуации, выходит из вертолета и просто стоит там. Вертолет остается заблокированным.

Установка:

1. Скачать

2. Разархивируйте архив

3. Распакуйте свою миссию PBO

4. Скопируйте папку scripts в корневую папку вашей миссии, если у вас уже есть папка scripts, скопируйте в нее папку JAEM.

5. Скопируйте папку dayz_code в корневую папку вашей миссии, если у вас ее еще нет. Если у вас уже есть папка dayz_code и те же файлы из предыдущей установки, вы отредактируете существующие файлы на шаге 7.

6. Откройте файл init.sqf и найдите строку:

call compile preprocessFileLineNumbers "\z\addons\dayz_code\init\variables.sqf";

Добавьте под ним следующую строку:

call compile preprocessFileLineNumbers "dayz_code\init\variables.sqf";

Найти строку:

call compile preprocessFileLineNumbers "\z\addons\dayz_code\init\compiles.sqf";

Добавьте под ним следующую строку:

call compile preprocessFileLineNumbers "dayz_code\init\compiles.sqf";

Найти строку:

waitUntil {scriptDone progress_monitor};

Добавьте над ним следующие строки:

execVM "scripts\JAEM\EvacChopper_init.sqf";

7. Если у вас уже есть кастомный файл fn_selfActions.sqf в каталоге dayz_code\compile, откройте этот файл. Если нет, вы должны были скопировать его из загрузки на шаге 5.

Найти код:

if (_isPZombie) then {
	if (s_player_attack < 0) then {
		s_player_attack = player addAction [localize "STR_EPOCH_ACTIONS_ATTACK", "\z\addons\dayz_code\actions\pzombie\pz_attack.sqf", _cursorTarget, 6, false, true];
	};
	if (s_player_callzombies < 0) then {
		s_player_callzombies = player addAction [localize "STR_EPOCH_ACTIONS_RAISEHORDE", "\z\addons\dayz_code\actions\pzombie\call_zombies.sqf",player, 5, true, false];
	};
	if (s_player_pzombiesvision < 0) then {
		s_player_pzombiesvision = player addAction [localize "STR_EPOCH_ACTIONS_NIGHTVIS", "\z\addons\dayz_code\actions\pzombie\pz_vision.sqf", [], 4, false, true, "nightVision", "_this == _target"];
	};
	if (!isNull _cursorTarget && (player distance _cursorTarget < 3)) then {
		_isZombie = _cursorTarget isKindOf "zZombie_base";
		_isHarvested = _cursorTarget getVariable["meatHarvested",false];
		_isMan = _cursorTarget isKindOf "Man"; //includes animals and zombies
		if (!alive _cursorTarget && _isMan && !_isZombie && !_isHarvested) then {
			if (s_player_pzombiesfeed < 0) then {
				s_player_pzombiesfeed = player addAction [localize "STR_EPOCH_ACTIONS_FEED", "\z\addons\dayz_code\actions\pzombie\pz_feed.sqf",_cursorTarget, 3, true, false];
			};
		} else {
			player removeAction s_player_pzombiesfeed;
			s_player_pzombiesfeed = -1;
		};
	} else {
		player removeAction s_player_pzombiesfeed;
		s_player_pzombiesfeed = -1;
	};
};

Добавьте под ним следующий блок кода.

Примечание: Если вы используете опцию Развертывание техники, вам не нужно использовать код, приведенный непосредственно ниже.

// Call EvacChopper
if (playerHasEvacField && {!evac_chopperUseClickActions}) then {
	if (player distance playersEvacField >= evac_chopperMinDistance && !evac_chopperInProgress && {isNull cursorTarget} && {speed player < 1} && {!_inVehicle}) then {
		if (evac_chopperNeedRadio == 1) then {
			if ("ItemRadio" in (items player)) then {
				if (s_player_evacCall < 0) then {
					s_player_evacCall = player addAction [("<t color=""#0000FF"">" + ("Call Evac-Chopper") + "</t>"),"scripts\JAEM\CallEvacChopper.sqf",[],-1000,false,false,"",""];
				};
			};
		} else {
			if (s_player_evacCall < 0) then {
				s_player_evacCall = player addAction [("<t color=""#0000FF"">" + ("Call Evac-Chopper") + "</t>"),"scripts\JAEM\CallEvacChopper.sqf",[],-1000,false,false,"",""];
			};
		};
	} else {
		player removeAction s_player_evacCall;
		s_player_evacCall = -1;
	};
};

Найдите блок кода:

// Allow Owner to lock and unlock vehicle
if (_player_lockUnlock_crtl) then {
	if (s_player_lockUnlock_crtl < 0) then {
		local _totalKeys = call epoch_tempKeys;
		local _temp_keys = _totalKeys select 0;
		local _temp_keys_names = _totalKeys select 1;
		local _hasKey = _characterID in _temp_keys;
		local _oldOwner = (_characterID == _uid);
		local _unlock = [];
		
		if (_isLocked) then {
			if (_hasKey || _oldOwner) then {
				_unlock = player addAction [format[localize "STR_EPOCH_ACTIONS_UNLOCK",_text], "\z\addons\dayz_code\actions\unlock_veh.sqf",[_cursorTarget,(_temp_keys_names select (_temp_keys find _characterID))], 2, true, true];
				s_player_lockunlock set [count s_player_lockunlock,_unlock];
				s_player_lockUnlock_crtl = 1;
			} else {
				if (_hasHotwireKit) then {
					_unlock = player addAction [format[localize "STR_EPOCH_ACTIONS_HOTWIRE",_text], "\z\addons\dayz_code\actions\hotwire_veh.sqf",_cursorTarget, 2, true, true];
				} else {
					_unlock = player addAction [format["<t color='#ff0000'>%1</t>",localize "STR_EPOCH_ACTIONS_VEHLOCKED"], "",_cursorTarget, 2, false, true];
				};
				s_player_lockunlock set [count s_player_lockunlock,_unlock];
				s_player_lockUnlock_crtl = 1;
			};
		} else {
			if (_hasKey || _oldOwner) then {
				_lock = player addAction [format[localize "STR_EPOCH_ACTIONS_LOCK",_text], "\z\addons\dayz_code\actions\lock_veh.sqf",_cursorTarget, 1, true, true];
				s_player_lockunlock set [count s_player_lockunlock,_lock];
				s_player_lockUnlock_crtl = 1;
			};
		};
	};
} else {
	{player removeAction _x} count s_player_lockunlock;s_player_lockunlock = [];
	s_player_lockUnlock_crtl = -1;
};

Замените весь блок кода следующим:

// Allow Owner to lock and unlock vehicle
if (_player_lockUnlock_crtl) then {
	local _totalKeys = call epoch_tempKeys;
	local _temp_keys = _totalKeys select 0;
	local _temp_keys_names = _totalKeys select 1;
	local _hasKey = _characterID in _temp_keys;
	local _oldOwner = (_characterID == _uid);
	if (s_player_lockUnlock_crtl < 0) then {
		local _unlock = [];
		
		if (_isLocked) then {
			if (_hasKey || _oldOwner) then {
				_unlock = player addAction [format[localize "STR_EPOCH_ACTIONS_UNLOCK",_text], "\z\addons\dayz_code\actions\unlock_veh.sqf",[_cursorTarget,(_temp_keys_names select (_temp_keys find _characterID))], 2, true, true];
				s_player_lockunlock set [count s_player_lockunlock,_unlock];
				s_player_lockUnlock_crtl = 1;
			} else {
				if (_hasHotwireKit) then {
					_unlock = player addAction [format[localize "STR_EPOCH_ACTIONS_HOTWIRE",_text], "\z\addons\dayz_code\actions\hotwire_veh.sqf",_cursorTarget, 2, true, true];
				} else {
					_unlock = player addAction [format["<t color='#ff0000'>%1</t>",localize "STR_EPOCH_ACTIONS_VEHLOCKED"], "",_cursorTarget, 2, false, true];
				};
				s_player_lockunlock set [count s_player_lockunlock,_unlock];
				s_player_lockUnlock_crtl = 1;
			};
		} else {
			if (_hasKey || _oldOwner) then {
				_lock = player addAction [format[localize "STR_EPOCH_ACTIONS_LOCK",_text], "\z\addons\dayz_code\actions\lock_veh.sqf",_cursorTarget, 1, true, true];
				s_player_lockunlock set [count s_player_lockunlock,_lock];
				s_player_lockUnlock_crtl = 1;
			};
		};
	};
	// EvacChopper
	if (s_player_evacChopper_ctrl < 0) then {
		if ((_cursorTarget isKindOf "Helicopter") && (_hasKey || _oldOwner) && !evac_chopperInProgress) then {
			if (!playerHasEvacField) then {
				local _setEvac = player addAction [("<t color=""#0000FF"">" + ("Set Evac-Chopper") + "</t>"),"scripts\JAEM\SetEvacChopper.sqf",_cursorTarget,3,false,true];
				s_player_evacChopper set [count s_player_evacChopper,_setEvac];
				s_player_evacChopper_ctrl = 1;
			};
			if (playerHasEvacField && (player distance playersEvacField < 10)) then {
				local _clearEvac = player addAction [("<t color=""#0000FF"">" + ("Clear Evac-Chopper") + "</t>"),"scripts\JAEM\ClearEvacChopper.sqf",_cursorTarget,4,false,true];
				s_player_evacChopper set [count s_player_evacChopper,_clearEvac];
				s_player_evacChopper_ctrl = 1;
			};
		};
	};
} else {
	{player removeAction _x} count s_player_lockunlock;s_player_lockunlock = [];
	s_player_lockUnlock_crtl = -1;
	{player removeAction _x} count s_player_evacChopper;s_player_evacChopper = [];
	s_player_evacChopper_ctrl = -1;
};

Найдите строку (около строки 1050):

s_player_lockUnlock_crtl = -1;

Добавьте под ним следующие строки:

{player removeAction _x} count s_player_evacChopper;s_player_evacChopper = [];
s_player_evacChopper_ctrl = -1;

8. Если у вас уже есть кастомный variables.sqf в каталоге dayz_code\init, откройте этот файл. Если нет, вы должны были скопировать его из загрузки на шаге 5.

Откройте кастомный variables.sqf и найдите строку:

 	//Player self-action handles

под этой строкой добавьте:

DayZ_SafeObjects set [count DayZ_SafeObjects, "HeliHRescue"];

// Evac Chopper Variables
playerHasEvacField = false; // DO NOT CHANGE.
playersEvacField = objNull; // DO NOT CHANGE.
s_player_evacChopper = []; // DO NOT CHANGE.
evac_chopperInProgress = false; //DO NOT CHANGE.

// Evac Chopper Config Variables
evac_chopperPrice = 1; // This is the price players pay in full briefcases to set up an evac chopper.
evac_chopperPriceZSC = 10000; // Price for evac chopper if you have ZSC Installed and evac_chopperUseZSC set to true.
evac_chopperAllowRefund = false; // Allow players to get their money back when they remove an evac-chopper field.
evac_chopperMinDistance = 500; // Minimum distance for player to call evac chopper. Do not set this lower than 500.
evac_chopperZoneMarker = 0; // Evac zone marker type (0 = Landingpad | 1 = Smoke).
evac_chopperNeedRadio = 0; // 1 - Require player to have a radio in gear to call evac chopper | 0 - Doesn't require radio to call evac chopper.
evac_chopperUseClickActions = false; // If you have Deploy Anything installed and are going to use click actions to call the evac chopper, set this to true (disables call chopper self-action loop).
evac_ChopperDisabledMarker = true; // Place a private map marker of the evac chopper's location

if (isServer) then {"CallEvacChopper" addPublicVariableEventHandler {(_this select 1) spawn server_callEvacChopper;};};

Если у вас уже есть этот раздел из предыдущей установки, просто добавьте следующие строки внизу над };

s_player_evacChopper_ctrl = -1;
s_player_evacCall = -1;

Убедитесь, что вы сравниваете свой файл с файлом, указанным в загрузке, чтобы строки оказались в правильном месте.

9. Если у вас уже есть кастомный compiles.sqf в каталоге dayz_code\init, откройте этот файл. Если нет, вы должны были скопировать его из загрузки на шаге 5.

Скопируйте следующую строку в раздел !isDedicated, если у вас ее еще нет в предыдущей установке:

	fnc_usec_selfactions = compile preprocessFileLineNumbers "dayz_code\compile\fn_selfActions.sqf";

10. Запакуйте свою миссию PBO

11. Распакуйте PBO вашего сервера и откройте dayz_server\system\server_monitor.sqf

Найдите эту строку:

dayz_serverIDMonitor = [];

Добавьте под ним следующую строку:

PVDZE_EvacChopperFields = [];

Найдите эту строку:

if (_type == "Base_Fire_DZ") then {_object spawn base_fireMonitor;};

Добавьте под ним следующую строку:

if (_type == "HeliHRescue") then {PVDZE_EvacChopperFields set [count PVDZE_EvacChopperFields, _object];};

Найдите эту строку:

publicVariable "sm_done";

Добавьте под ним следующий блок кода:

publicVariable "PVDZE_EvacChopperFields";
ON_fnc_evacChopperFieldsUpdate = {
	local _action = _this select 0;
	local _field = _this select 1;
	if (_action == "add") then {PVDZE_EvacChopperFields = PVDZE_EvacChopperFields + [_field];};
	if (_action == "rem") then {PVDZE_EvacChopperFields = PVDZE_EvacChopperFields - [_field];};
	publicVariable "PVDZE_EvacChopperFields";
};
"PVDZE_EvacChopperFieldsUpdate" addPublicVariableEventHandler {(_this select 1) call ON_fnc_evacChopperFieldsUpdate};

Сохраняем и закрываем

12. Откройте dayz_server\init\server_functions.sqf

Найдите эту строку:

spawn_vehicles = compile preprocessFileLineNumbers "\z\addons\dayz_server\compile\spawn_vehicles.sqf";

Добавьте под ним следующую строку:

server_callEvacChopper = compile preprocessFileLineNumbers "\z\addons\dayz_server\compile\server_callEvacChopper.sqf";

Сохраняем и закрываем

13. Скопируйте файл dayz_server\compile\server_callEvacChopper.sqf в папку вашего сервера.

14. Запаковать сервер PBO

15. Полный набор необходимых файлов BattlEye был предоставлен в папке BattlEye. Если у вас новый сервер или вы предпочитаете диффмердж, вы можете использовать эти файлы. В противном случае следуйте приведенным ниже инструкциям.

Настройка Battleye фильтров:

1. Открыть файл publicvariable.txt

Добавьте это в конец строки 2:

!=PVDZE_EvacChopperFieldsUpdate !=CallEvacChopper

2. Открыть файл createvehicle.txt

Добавьте это в конец строки 2:

!="HeliHRescue"

3. Открыть файл scripts.txt

Добавьте это в конец строки 17:

!"\\dayz_code\\init\\compiles.sqf\"\nif (!isDedicated) then {\ndiag_log \"Loading custom client com"

Добавьте это в конец строки 2:

!=" (s_player_evacCall < 0) then {\ns_player_evacCall = player addAction [(\"<t color=\"\"#0000FF\"\">\" + (\"Call Evac-Chopper\") + \"</t>\")"

Добавьте это в конец строки 21:

!="time = time;\n_chopperPos = getPos _evacChopper;\n_marker = createMarkerLocal [\"EvacChopper\",_chopperPos];\n_marker setMarkerColorL"

Добавьте это в конец строки 27:

!="me) > evac_chopperMarkerTimeout) then {_recovered = true; deleteMarkerLocal _marker; \"EVAC Chopper map marker deleted\" call dayz"

Добавьте это в конец строки 38:

!="_this select 4;};\n\nif (_flightStatus == \"Arrived\") exitWith\n{\nhintSilent parseText format [\"\n			<t size='1.15'	font='Bitstream'a"

Добавьте это в конец строки 58:

!="= createMarkerLocal [\"EvacChopper\",_chopperPos];\n_marker setMarkerColorLocal \"ColorBlack\";\n_marker setMarkerTypeLocal \"mil_objec"

Добавьте это в конец строки 63:

!="ck\";\n_marker setMarkerTypeLocal \"mil_objective\";\n_marker setMarkerTextLocal \"EvacChopper\";\nwhile {!_recovered} do {\nif (!alive _"

Добавьте это в конец строки 64:

!="rPos];\n_marker setMarkerColorLocal \"ColorBlack\";\n_marker setMarkerTypeLocal \"mil_objective\";\n_marker setMarkerTextLocal \"EvacCho"

Добавьте это в конец строки 72:

!="FNC_GetPos;\n_canceled = false;\n\n\nfor \"_p\" from 1 to 5 do\n{\nsystemChat(format [\"Evac-Chopper get called in %1s - Move to cancel!\""

Настройка развертывание техники:

1. Если вы хотите использовать действия по щелчку правой кнопкой мыши при развертывании чего-либо для вызова прерывателя эвакуации вместо встроенных самостоятельных действий, найдите эту переменную в кастомном variables.sqf:

Найдите эту переменную

evac_chopperUseClickActions = false;

и измените на:

evac_chopperUseClickActions = true;

Откройте файл вашей миссии и найдите файл overwrites\click_actions\config.sqf.

Добавьте это в нижнюю часть массива DZE_CLICK_ACTIONS:

["ItemGPS","Call Evac Chopper","execVM 'scripts\JAEM\callEvacChopper.sqf';","true"]

Примечание: вы можете привязать действие щелчка правой кнопкой мыши к любому элементу ремня для инструментов. Я просто выбрал ItemGPS по умолчанию. Убедитесь, что вы поставили запятую на предпоследней.

Так-же в файле scripts.txt в конец строки 32 добавить:

!="execVM 'scripts\\JAEM\\callEvacChopper.sqf';"

Оригинал статьи: epochmod.com

Sign In

JAEM | Эвакуационный вертолет

Recommended Posts

Share this post

Link to post

Share on other sites

Create an account or sign in to comment

Create an account

Sign in

Similar Content

Our picks

Персональный скин, точка спавна, и сет с лутом при респавне, стартовый лут для всех!

Создаем свой серверный мод. [DayZ 1.4 to Discontined]

Увеличение карты х2

Future of the S-Platoon project

Marketplace

My account

Important Information