Охлаждение еды и кастрюли после готовки

Борис, ошибка LineHit

48 минут назад, OskarDallas сказал:

Борис, ошибка LineHit

ну ят у себя пофиксил ))))))))))

дай ссыл на тему

ща обновлю

 

3 минуты назад, BorizzK сказал:

ну ят у себя пофиксил ))))))))))

дай ссыл на тему

ща обновлю

 

Так ты ж в ней )) Это твой пост по охлаждению) 

Блин

Туплю ))))))))

 

//09.06.2020

modded class ItemBase extends InventoryItem
{
	ref Timer m_TemperatureDecrease;

	private float m_InitTemperature;
	private float m_DecreaseTempTime 		= 10;
	private float m_TempDecreaseCoef		= 1;
	
	private float m_DamageTemperaturePlayer = 51;
	private float m_TempDamageCoef			= 0.015;

	private int	m_CurrentLocation			= InventoryLocationType.GROUND;
	
	// ==================================================================================================================

	private bool m_DecTempAllow	= true;
	
	bool IsDecTempAllow()
	{
		return m_DecTempAllow;
	}
	
	void SetDecTempAllow(bool value = true) //Uses for stop/start decrease temp if cooking on fireplace etc. //Используем для остановки остывания во время готовки и запуска остывания после прекращения
	{
		m_DecTempAllow = value;

		//Print("::: SERVER: [ItemBase extends InventoryItem: Decreasetemp]: SetDecTempAllow: " + GetGame().GetTickTime() + ": this: " + this + ": m_DecTempAllow: " + m_DecTempAllow);

		if (!m_DecTempAllow)
		{
			if (m_TemperatureDecrease)
			{
				StopTemperatureDecrease();
			}
		}
		else
		{
			TryToStartTempDecrease();
		}

		if (GetInventory().GetCargo())
		{
			SetDecTempAllowToCargo(value);
		}
	}
	
	void SetDecTempAllowToCargo(bool value = true) //End-to-end call for all inventory in cargo //Сквозной вызов для всего инвентаря
	{
		ItemBase item;

		//Print("::: SERVER: [ItemBase extends InventoryItem: Decreasetemp]: SetDecTempAllowToCargo: " + GetGame().GetTickTime() + ": this: " + this + ": Items count: " + GetInventory().GetCargo().GetItemCount() + ": m_DecTempAllow: " + m_DecTempAllow);

		for (int i = 0; i < GetInventory().GetCargo().GetItemCount(); i++)
		{
			item = ItemBase.Cast(GetInventory().GetCargo().GetItem(i));
			if (item)
			{
				if (item.IsDecTempAllow() != value) item.SetDecTempAllow(value);
			}
		}
	}

	// ==================================================================================================================

	void ItemBase()
	{
		m_InitTemperature = 20;
		if ( IsInherited(Pot) )
		{
			m_TempDecreaseCoef = m_TempDecreaseCoef * 2;
		}
		else if (IsInherited(FireplaceBase))
		{
			m_DecTempAllow = false;
		}
	}

	void ~ItemBase()
	{
		if (m_TemperatureDecrease)
		{
			StopTemperatureDecrease();
		}
	}

	// ==================================================================================================================

	override void AfterStoreLoad()
	{	
		super.AfterStoreLoad();
		
		if ( !IsInherited(FireplaceBase) ) TryToStartTempDecrease();
	}

	private void TryToStartTempDecrease()
	{
		if (GetTemperature() > GetInitTemperature())
		{
			if (GetHierarchyParent())
			{
				if (GetHierarchyParent().IsInherited(PlayerBase))
				{
					PlayerBase player = PlayerBase.Cast(GetHierarchyParent());
					if (player)
					{
						if (player.GetHumanInventory().GetEntityInHands() == this)
						{
							m_CurrentLocation = InventoryLocationType.HANDS;
						}
					}
					else
					{
						m_CurrentLocation = -1; //Игрок есть, но он не на сервере!
					}
				}
			}

			if (m_CurrentLocation != -1)
			{
				if (!m_TemperatureDecrease)
				{
					//Print("::: SERVER: [ItemBase extends InventoryItem: Decreasetemp]: TryToStartTempDecrease: " + GetGame().GetTickTime() + ": this: " + this + ": Start decrease temperature: GetTemperature(): " + GetTemperature() + ": GetHierarchyParent(): " + GetHierarchyParent());
					StartTemperatureDecrease();
				}
			}
		}
	}

	// ==================================================================================================================

	override void EEItemLocationChanged(notnull InventoryLocation oldLoc, notnull InventoryLocation newLoc)
	{
		super.EEItemLocationChanged(oldLoc,newLoc);
		
		if (GetTemperature() > GetInitTemperature())
		{
			if ( !IsInherited(FireplaceBase) )
			{
				m_CurrentLocation = newLoc.GetType();
				if (!m_TemperatureDecrease)
				{
					m_DecTempAllow = true;
					//Print("::: SERVER: [ItemBase extends InventoryItem: Decreasetemp]: EEItemLocationChanged: " + GetGame().GetTickTime() + ": this: " + this + ": Start decrease temperature: GetTemperature(): " + GetTemperature() + ": newLoc.GetParent(): " + newLoc.GetParent());
					StartTemperatureDecrease();
				}
			}
		}
		else
		{
			if (m_TemperatureDecrease)
			{
				//Print("::: SERVER: [ItemBase extends InventoryItem: Decreasetemp]: EEItemLocationChanged: " + GetGame().GetTickTime() + ": this: " + this + ": End decrease temperature: GetTemperature(): " + GetTemperature() + ": newLoc.GetParent(): " + newLoc.GetParent());
				StopTemperatureDecrease();
			}
		}
	}

	// ==================================================================================================================

	private void StartTemperatureDecrease()
	{
		DecreaseTemperature();
		m_TemperatureDecrease = new Timer;
		m_TemperatureDecrease.Run(m_DecreaseTempTime, this, "DecreaseTemperature", NULL, true);
	}
	
	private void StopTemperatureDecrease()
	{
		m_CurrentLocation = InventoryLocationType.UNKNOWN;
		m_TemperatureDecrease.Stop();
		m_TemperatureDecrease = NULL;
	}

	// == COOLING ==
	void DecreaseTemperature()
	{
		if (GetTemperature() > GetInitTemperature())
		{
			if (m_CurrentLocation == InventoryLocationType.HANDS)
			{
				if (GetTemperature() >= GetDamageTemperaturePlayer())
				{
					AddTemperatureDamageToPlayer();
				}
			}
			AddTemperature(-GetTempDecreaseCoef());
			//Print("::: SERVER: [ItemBase extends InventoryItem: Decreasetemp]: DecreaseTemperature: " + GetGame().GetTickTime() + ": this: " + this + ": Decrease: GetTemperature(): " + GetTemperature());
		}
		else
		{
			SetTemperature(GetInitTemperature());
			StopTemperatureDecrease();
			//Print("::: SERVER: [ItemBase extends InventoryItem: Decreasetemp]: DecreaseTemperature: " + GetGame().GetTickTime() + ": this: " + this + ": Stop decrease: GetTemperature(): " + GetTemperature());
		}
	}

	private bool m_CargoDecTempState = false;
	void DecreaseCargoTemperature()
	{
		ItemBase item;
		m_CargoDecTempState = false;
		int item_count = GetInventory().GetCargo().GetItemCount();
		for (int i = 0; i < item_count; i++)
		{
			item = ItemBase.Cast(GetInventory().GetCargo().GetItem(i));
			if (item)
			{
				if (item.GetTemperature() > item.GetInitTemperature())
				{
					m_CargoDecTempState = true;
					item.AddTemperature(-item.GetTempDecreaseCoef());
					//Print("::: SERVER: [ItemBase extends InventoryItem: Decreasetemp]: DecreaseCargoTemperature: " + GetGame().GetTickTime() + ": this: " + this + ": Decrease: item: " + item + ":  item.GetTemperature(): " + item.GetTemperature());
				}
				else
				{
					item.SetTemperature(item.GetInitTemperature());
					//Print("::: SERVER: [ItemBase extends InventoryItem: Decreasetemp]: DecreaseCargoTemperature: " + GetGame().GetTickTime() + ": this: " + this + ": Stop decrease: item: " + item + ":  item.GetTemperature(): " + item.GetTemperature());
				}
			}
		}
	}
	// == COOLING END ==

	// ==================================================================================================================
	
	// == DAMAGE ==
	void AddTemperatureDamageToPlayer()
	{
		PlayerBase player = PlayerBase.Cast(GetHierarchyParent());
		if (player && player.IsAlive())
		{
			float idmg = GetDamageTemperature();

			ItemBase gloves = ItemBase.Cast(player.GetInventory().FindAttachment(InventorySlots.GLOVES));
			if (gloves)
			{
				gloves.AddHealth("","Health", -idmg);
				//Print("::: SERVER: [ItemBase extends InventoryItem: Decreasetemp]: AddTemperatureDamageToParent: " + GetGame().GetTickTime() + ": this: " + this + ": player: " + player + ": idmg: " + idmg + ": Gloves Health: " + gloves.GetHealth() + ": Gloves Max Health: " + gloves.GetMaxHealth());
				if (gloves.GetHealth() > gloves.GetMaxHealth() * 0.5)
				{
					return;
				}
				else if (gloves.GetHealth() > gloves.GetMaxHealth() * 0.25)
				{
					idmg = idmg * 0.75;
				}
			}

			player.ProcessDirectDamage(DT_CUSTOM, this, "RightHand", "FireDamage", "0.5 0.5 0.5", idmg * 0.42);
			if (IsInherited(Pot)) player.ProcessDirectDamage(DT_CUSTOM, this, "LeftHand", "FireDamage", "0.5 0.5 0.5", idmg * 0.42);
			//Print("::: SERVER: [ItemBase extends InventoryItem: Decreasetemp]: AddTemperatureDamageToParent: " + GetGame().GetTickTime() + ": this: " + this + ": player: " + player + ": idmg: " + idmg + ": Health: " + player.GetHealth() + ": RightHand: " + player.GetHealth("RightHand","Health") + ": LeftHand: " + player.GetHealth("LeftHand","Health"));
		}
	}
	
	float GetDamageTemperaturePlayer()
	{
		return m_DamageTemperaturePlayer;
	}
	
	float GetDamageTemperature()
	{
		return GetTemperature() * m_TempDamageCoef;
	}
	// == DAMAGE END ==
	
	// ==================================================================================================================

	float GetInitTemperature()
	{
		return m_InitTemperature;
	}

	float GetTempDecreaseCoef()
	{
		if (!IsUnderRoof())
		{
			return m_TempDecreaseCoef * (1 + GetRainAbove());
		}
		return m_TempDecreaseCoef;
	}
	
	float GetRainAbove()
	{
		return GetGame().GetWeather().GetRain().GetActual();
	}

	bool IsUnderRoof()
	{
		return MiscGameplayFunctions.IsUnderRoof( this );
	}

	// ==================================================================================================================
}

	// ==================================================================================================================
	// ==================================================================================================================

modded class FireplaceBase extends ItemBase
{
	const float PARAM_COOKING_EQUIP_TEMP_INCREASE	= 1; //10

	override void DestroyFireplace()
	{
		if (m_CookingEquipment) 
		{
			if (m_CookingEquipment.IsInherited(Pot))
			{
				m_CookingEquipment.SetDecTempAllow(true);
			}
		}
		super.DestroyFireplace();
	}
	
	//Add cooking equipment
	override void SetCookingEquipment( ItemBase equipment )
	{
		super.SetCookingEquipment( equipment );
		m_CookingEquipment = equipment;
		if (m_CookingEquipment)
		{
			if (m_CookingEquipment.IsInherited(Pot))
			{
				//Print("::: SERVER: [FireplaceBase extends ItemBase: Decreasetemp]: SetCookingEquipment: " + GetGame().GetTickTime() + ": this: " + this + ": m_CookingEquipment " + m_CookingEquipment);
				if (m_HeatingTimer)
				{
					m_CookingEquipment.SetDecTempAllow(false);
				}
				else
				{
					m_CookingEquipment.SetDecTempAllow(true);
				}
			}
		}
		
	}

	//Start heating
	override protected void StartHeating()
	{
		if (m_CookingEquipment && m_CookingEquipment.IsInherited(Pot))
		{
			//Print("::: SERVER: [FireplaceBase extends ItemBase: Decreasetemp]: StartHeating: " + GetGame().GetTickTime() + ": this: " + this + ": m_CookingEquipment " + m_CookingEquipment);
			m_CookingEquipment.SetDecTempAllow(false);
		}
		super.StartHeating();
	}

	//Stop heating
	override protected void StopHeating()
	{
		super.StopHeating();
		if (m_CookingEquipment && m_CookingEquipment.IsInherited(Pot))
		{
			//Print("::: SERVER: [FireplaceBase extends ItemBase: Decreasetemp]: StopHeating: " + GetGame().GetTickTime() + ": this: " + this + ": m_CookingEquipment " + m_CookingEquipment);
			m_CookingEquipment.SetDecTempAllow(true);
		}
	}	
}

Думается над еще подкрутить но народ грит норм потому пока не буду

Если есть идеи - пишите сюда

Изменено 30 июня 2020 пользователем BorizzK (история изменений)

Как это все замодить ?

 

26 минут назад, fantom3888 сказал:

Как это все замодить ?

 

 

Борис, не совсем верно работает. Тара не остывает. При этом тара резко остывает с 200 до 100

Изменено 1 июля 2020 пользователем OskarDallas (история изменений)

37 минут назад, OskarDallas сказал:

Борис, не совсем верно работает. Тара не остывает. При этом тара резко остывает с 200 до 100

протестируем

 

тара?

Да, если снять с костра кастрюлю, или с печки сковороду, то остывания нет, сразу падает с 200 на 100 и стоит на месте

21 минуту назад, OskarDallas сказал:

Да, если снять с костра кастрюлю, или с печки сковороду, то остывания нет, сразу падает с 200 на 100 и стоит на месте

посмотрим сеня

 

Спасибо

Так

Игра больше не кажет 200 град

она показывает более 100 если т выше 100 град

а вот ниже уже начинает показывать реальную т

 

Спасибо за скрипт. Использую. Но почему то падение здоровья бывает багается из за температурного воздействия, будь это перегрев или переохлаждение. Падение здоровья помогает остановить перезаход на сервер. По возможности посмотрите, может быть можно с этим что то сделать? Спасибо.

Есть нюансы

После обновы

Нужно переписывать логику тк теперь готовка еще и в директслотах итд итп

вобщем есть ощущение (еще не изучал) что скриптец может сажать серверный фпс

завтра засяду переделывать

Очень интересно,когда ждать обновлённую версию?

14.07.2020 в 20:35, BorizzK сказал:

Есть нюансы

После обновы

Нужно переписывать логику тк теперь готовка еще и в директслотах итд итп

вобщем есть ощущение (еще не изучал) что скриптец может сажать серверный фпс

завтра засяду переделывать

Мда, если персонаж замёрз то это уже не остановить. Даже перезаход не помогает. Обламывает контент с холодной погодой и необходимостью отогреваться. Скажите, ведутся ли работы по этой теме?

Здравствуйте. Стоит ждать обновленной версии скрипта?

Стоит

 

Борис, доделай уже )